1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
|
/*********************************************************************/
/* Copyright 2009, 2010 The University of Texas at Austin. */
/* All rights reserved. */
/* */
/* Redistribution and use in source and binary forms, with or */
/* without modification, are permitted provided that the following */
/* conditions are met: */
/* */
/* 1. Redistributions of source code must retain the above */
/* copyright notice, this list of conditions and the following */
/* disclaimer. */
/* */
/* 2. Redistributions in binary form must reproduce the above */
/* copyright notice, this list of conditions and the following */
/* disclaimer in the documentation and/or other materials */
/* provided with the distribution. */
/* */
/* THIS SOFTWARE IS PROVIDED BY THE UNIVERSITY OF TEXAS AT */
/* AUSTIN ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, */
/* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF */
/* MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE */
/* DISCLAIMED. IN NO EVENT SHALL THE UNIVERSITY OF TEXAS AT */
/* AUSTIN OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, */
/* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES */
/* (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE */
/* GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR */
/* BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF */
/* LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT */
/* (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT */
/* OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE */
/* POSSIBILITY OF SUCH DAMAGE. */
/* */
/* The views and conclusions contained in the software and */
/* documentation are those of the authors and should not be */
/* interpreted as representing official policies, either expressed */
/* or implied, of The University of Texas at Austin. */
/*********************************************************************/
#define ASSEMBLER
#include "common.h"
#ifndef WINDOWS_ABI
#define M ARG1
#define X ARG4
#define INCX ARG5
#define Y ARG6
#define INCY ARG2
#else
#define M ARG1
#define X ARG2
#define INCX ARG3
#define Y ARG4
#define INCY %r10
#endif
#define YY %r11
#define ALPHA_R %xmm14
#define ALPHA_I %xmm15
#include "l1param.h"
PROLOGUE
PROFCODE
#ifndef WINDOWS_ABI
#ifndef XDOUBLE
movq 8(%rsp), INCY
#else
movq 40(%rsp), INCY
#endif
#else
movaps %xmm3, %xmm0
movsd 40(%rsp), %xmm1
movq 48(%rsp), X
movq 56(%rsp), INCX
movq 64(%rsp), Y
movq 72(%rsp), INCY
#endif
SAVEREGISTERS
#ifndef CONJ
#define ADD1 subsd
#define ADD2 addsd
#else
#define ADD1 addsd
#define ADD2 subsd
#endif
salq $ZBASE_SHIFT, INCX
movaps %xmm0, ALPHA_R
salq $ZBASE_SHIFT, INCY
movaps %xmm1, ALPHA_I
testq M, M
jle .L999
cmpq $2 * SIZE, INCX
jne .L20
cmpq $2 * SIZE, INCY
jne .L20
movq M, %rax
sarq $2, %rax
jle .L15
movsd 0 * SIZE(X), %xmm0
movsd 1 * SIZE(X), %xmm1
movsd 0 * SIZE(Y), %xmm8
movsd 1 * SIZE(Y), %xmm9
movsd 2 * SIZE(X), %xmm4
movsd 3 * SIZE(X), %xmm5
movsd 2 * SIZE(Y), %xmm10
movsd 3 * SIZE(Y), %xmm11
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
mulsd ALPHA_I, %xmm3
mulsd ALPHA_I, %xmm2
movaps %xmm4, %xmm6
mulsd ALPHA_R, %xmm4
addsd %xmm0, %xmm8
movsd 4 * SIZE(X), %xmm0
movaps %xmm5, %xmm7
mulsd ALPHA_R, %xmm5
ADD2 %xmm1, %xmm9
movsd 5 * SIZE(X), %xmm1
decq %rax
jle .L12
ALIGN_3
.L11:
#ifdef PREFETCH
PREFETCH (PREFETCHSIZE + 0) - PREOFFSET(X)
#endif
mulsd ALPHA_I, %xmm7
movsd 4 * SIZE(Y), %xmm12
ADD1 %xmm3, %xmm8
mulsd ALPHA_I, %xmm6
movsd 5 * SIZE(Y), %xmm13
addsd %xmm2, %xmm9
addsd %xmm4, %xmm10
movsd 6 * SIZE(X), %xmm4
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
ADD2 %xmm5, %xmm11
movsd 7 * SIZE(X), %xmm5
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
ADD1 %xmm7, %xmm10
movsd %xmm8, 0 * SIZE(Y)
mulsd ALPHA_I, %xmm3
addsd %xmm6, %xmm11
movsd %xmm9, 1 * SIZE(Y)
mulsd ALPHA_I, %xmm2
movaps %xmm4, %xmm6
movsd %xmm10, 2 * SIZE(Y)
mulsd ALPHA_R, %xmm4
movsd 6 * SIZE(Y), %xmm10
addsd %xmm0, %xmm12
movsd 8 * SIZE(X), %xmm0
#ifdef PREFETCHW
PREFETCHW (PREFETCHSIZE + 0) - PREOFFSET(Y)
#endif
movaps %xmm5, %xmm7
movsd %xmm11, 3 * SIZE(Y)
mulsd ALPHA_R, %xmm5
movsd 7 * SIZE(Y), %xmm11
ADD2 %xmm1, %xmm13
movsd 9 * SIZE(X), %xmm1
mulsd ALPHA_I, %xmm7
movsd 8 * SIZE(Y), %xmm8
ADD1 %xmm3, %xmm12
mulsd ALPHA_I, %xmm6
movsd 9 * SIZE(Y), %xmm9
addsd %xmm2, %xmm13
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
addsd %xmm4, %xmm10
movsd 10 * SIZE(X), %xmm4
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
ADD2 %xmm5, %xmm11
movsd 11 * SIZE(X), %xmm5
mulsd ALPHA_I, %xmm3
movsd %xmm12, 4 * SIZE(Y)
ADD1 %xmm7, %xmm10
mulsd ALPHA_I, %xmm2
movsd %xmm13, 5 * SIZE(Y)
addsd %xmm6, %xmm11
movaps %xmm4, %xmm6
movsd %xmm10, 6 * SIZE(Y)
mulsd ALPHA_R, %xmm4
addsd %xmm0, %xmm8
movsd 10 * SIZE(Y), %xmm10
movsd 12 * SIZE(X), %xmm0
movaps %xmm5, %xmm7
movsd %xmm11, 7 * SIZE(Y)
mulsd ALPHA_R, %xmm5
movsd 11 * SIZE(Y), %xmm11
ADD2 %xmm1, %xmm9
movsd 13 * SIZE(X), %xmm1
addq $8 * SIZE, X
addq $8 * SIZE, Y
decq %rax
jg .L11
ALIGN_3
.L12:
mulsd ALPHA_I, %xmm7
movsd 4 * SIZE(Y), %xmm12
ADD1 %xmm3, %xmm8
mulsd ALPHA_I, %xmm6
movsd 5 * SIZE(Y), %xmm13
addsd %xmm2, %xmm9
addsd %xmm4, %xmm10
movsd 6 * SIZE(X), %xmm4
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
ADD2 %xmm5, %xmm11
movsd 7 * SIZE(X), %xmm5
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
ADD1 %xmm7, %xmm10
movsd %xmm8, 0 * SIZE(Y)
mulsd ALPHA_I, %xmm3
addsd %xmm6, %xmm11
movsd %xmm9, 1 * SIZE(Y)
mulsd ALPHA_I, %xmm2
movaps %xmm4, %xmm6
movsd %xmm10, 2 * SIZE(Y)
mulsd ALPHA_R, %xmm4
movsd 6 * SIZE(Y), %xmm10
addsd %xmm0, %xmm12
movaps %xmm5, %xmm7
movsd %xmm11, 3 * SIZE(Y)
mulsd ALPHA_R, %xmm5
ADD2 %xmm1, %xmm13
movsd 7 * SIZE(Y), %xmm11
mulsd ALPHA_I, %xmm7
ADD1 %xmm3, %xmm12
mulsd ALPHA_I, %xmm6
addsd %xmm2, %xmm13
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
addsd %xmm4, %xmm10
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
ADD2 %xmm5, %xmm11
mulsd ALPHA_I, %xmm3
ADD1 %xmm7, %xmm10
addsd %xmm6, %xmm11
mulsd ALPHA_I, %xmm2
movsd %xmm12, 4 * SIZE(Y)
movsd %xmm13, 5 * SIZE(Y)
movsd %xmm10, 6 * SIZE(Y)
movsd %xmm11, 7 * SIZE(Y)
addq $8 * SIZE, X
addq $8 * SIZE, Y
ALIGN_3
.L15:
movq M, %rax
andq $2, %rax
jle .L17
movsd 0 * SIZE(X), %xmm0
movsd 1 * SIZE(X), %xmm1
movsd 2 * SIZE(X), %xmm4
movsd 3 * SIZE(X), %xmm5
movaps %xmm0, %xmm2
movsd 0 * SIZE(Y), %xmm8
mulsd ALPHA_R, %xmm0
movaps %xmm1, %xmm3
movsd 1 * SIZE(Y), %xmm9
mulsd ALPHA_R, %xmm1
movsd 2 * SIZE(Y), %xmm10
mulsd ALPHA_I, %xmm3
movsd 3 * SIZE(Y), %xmm11
mulsd ALPHA_I, %xmm2
movaps %xmm4, %xmm6
mulsd ALPHA_R, %xmm4
addsd %xmm0, %xmm8
movaps %xmm5, %xmm7
mulsd ALPHA_R, %xmm5
ADD2 %xmm1, %xmm9
mulsd ALPHA_I, %xmm7
ADD1 %xmm3, %xmm8
mulsd ALPHA_I, %xmm6
addsd %xmm2, %xmm9
addsd %xmm4, %xmm10
movsd %xmm8, 0 * SIZE(Y)
ADD2 %xmm5, %xmm11
movsd %xmm9, 1 * SIZE(Y)
ADD1 %xmm7, %xmm10
addsd %xmm6, %xmm11
movsd %xmm10, 2 * SIZE(Y)
movsd %xmm11, 3 * SIZE(Y)
addq $4 * SIZE, X
addq $4 * SIZE, Y
ALIGN_3
.L17:
movq M, %rax
andq $1, %rax
jle .L999
movsd 0 * SIZE(X), %xmm0
movsd 1 * SIZE(X), %xmm1
movsd 0 * SIZE(Y), %xmm8
movsd 1 * SIZE(Y), %xmm9
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
mulsd ALPHA_I, %xmm3
mulsd ALPHA_I, %xmm2
addsd %xmm0, %xmm8
ADD2 %xmm1, %xmm9
ADD1 %xmm3, %xmm8
addsd %xmm2, %xmm9
movsd %xmm8, 0 * SIZE(Y)
movsd %xmm9, 1 * SIZE(Y)
jmp .L999
ALIGN_3
.L20:
movq Y, YY
movq M, %rax
sarq $2, %rax
jle .L25
movsd 0 * SIZE(X), %xmm0
movsd 1 * SIZE(X), %xmm1
addq INCX, X
movsd 0 * SIZE(Y), %xmm8
movsd 1 * SIZE(Y), %xmm9
addq INCY, Y
movsd 0 * SIZE(X), %xmm4
movsd 1 * SIZE(X), %xmm5
addq INCX, X
movsd 0 * SIZE(Y), %xmm10
movsd 1 * SIZE(Y), %xmm11
addq INCY, Y
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
mulsd ALPHA_I, %xmm3
mulsd ALPHA_I, %xmm2
movaps %xmm4, %xmm6
mulsd ALPHA_R, %xmm4
addsd %xmm0, %xmm8
movsd 0 * SIZE(X), %xmm0
movaps %xmm5, %xmm7
mulsd ALPHA_R, %xmm5
ADD2 %xmm1, %xmm9
movsd 1 * SIZE(X), %xmm1
addq INCX, X
decq %rax
jle .L22
ALIGN_3
.L21:
mulsd ALPHA_I, %xmm7
movsd 0 * SIZE(Y), %xmm12
ADD1 %xmm3, %xmm8
mulsd ALPHA_I, %xmm6
movsd 1 * SIZE(Y), %xmm13
addsd %xmm2, %xmm9
addq INCY, Y
addsd %xmm4, %xmm10
movsd 0 * SIZE(X), %xmm4
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
ADD2 %xmm5, %xmm11
movsd 1 * SIZE(X), %xmm5
movaps %xmm1, %xmm3
addq INCX, X
mulsd ALPHA_R, %xmm1
ADD1 %xmm7, %xmm10
movsd %xmm8, 0 * SIZE(YY)
mulsd ALPHA_I, %xmm3
addsd %xmm6, %xmm11
movsd %xmm9, 1 * SIZE(YY)
mulsd ALPHA_I, %xmm2
addq INCY, YY
movaps %xmm4, %xmm6
movsd %xmm10, 0 * SIZE(YY)
mulsd ALPHA_R, %xmm4
movsd 0 * SIZE(Y), %xmm10
addsd %xmm0, %xmm12
movsd 0 * SIZE(X), %xmm0
movaps %xmm5, %xmm7
movsd %xmm11, 1 * SIZE(YY)
addq INCY, YY
mulsd ALPHA_R, %xmm5
movsd 1 * SIZE(Y), %xmm11
addq INCY, Y
ADD2 %xmm1, %xmm13
movsd 1 * SIZE(X), %xmm1
addq INCX, X
mulsd ALPHA_I, %xmm7
movsd 0 * SIZE(Y), %xmm8
ADD1 %xmm3, %xmm12
mulsd ALPHA_I, %xmm6
movsd 1 * SIZE(Y), %xmm9
addsd %xmm2, %xmm13
addq INCY, Y
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
addsd %xmm4, %xmm10
movsd 0 * SIZE(X), %xmm4
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
ADD2 %xmm5, %xmm11
movsd 1 * SIZE(X), %xmm5
addq INCX, X
mulsd ALPHA_I, %xmm3
movsd %xmm12, 0 * SIZE(YY)
ADD1 %xmm7, %xmm10
mulsd ALPHA_I, %xmm2
movsd %xmm13, 1 * SIZE(YY)
addsd %xmm6, %xmm11
addq INCY, YY
movaps %xmm4, %xmm6
movsd %xmm10, 0 * SIZE(YY)
mulsd ALPHA_R, %xmm4
addsd %xmm0, %xmm8
movsd 0 * SIZE(Y), %xmm10
movsd 0 * SIZE(X), %xmm0
movaps %xmm5, %xmm7
movsd %xmm11, 1 * SIZE(YY)
addq INCY, YY
mulsd ALPHA_R, %xmm5
movsd 1 * SIZE(Y), %xmm11
addq INCY, Y
ADD2 %xmm1, %xmm9
movsd 1 * SIZE(X), %xmm1
addq INCX, X
decq %rax
jg .L21
ALIGN_3
.L22:
mulsd ALPHA_I, %xmm7
movsd 0 * SIZE(Y), %xmm12
ADD1 %xmm3, %xmm8
mulsd ALPHA_I, %xmm6
movsd 1 * SIZE(Y), %xmm13
addsd %xmm2, %xmm9
addq INCY, Y
addsd %xmm4, %xmm10
movsd 0 * SIZE(X), %xmm4
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
ADD2 %xmm5, %xmm11
movsd 1 * SIZE(X), %xmm5
movaps %xmm1, %xmm3
addq INCX, X
mulsd ALPHA_R, %xmm1
ADD1 %xmm7, %xmm10
movsd %xmm8, 0 * SIZE(YY)
mulsd ALPHA_I, %xmm3
addsd %xmm6, %xmm11
movsd %xmm9, 1 * SIZE(YY)
mulsd ALPHA_I, %xmm2
addq INCY, YY
movaps %xmm4, %xmm6
movsd %xmm10, 0 * SIZE(YY)
mulsd ALPHA_R, %xmm4
movsd 0 * SIZE(Y), %xmm10
addsd %xmm0, %xmm12
movaps %xmm5, %xmm7
movsd %xmm11, 1 * SIZE(YY)
mulsd ALPHA_R, %xmm5
addq INCY, YY
ADD2 %xmm1, %xmm13
movsd 1 * SIZE(Y), %xmm11
mulsd ALPHA_I, %xmm7
addq INCY, Y
ADD1 %xmm3, %xmm12
mulsd ALPHA_I, %xmm6
addsd %xmm2, %xmm13
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
addsd %xmm4, %xmm10
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
ADD2 %xmm5, %xmm11
mulsd ALPHA_I, %xmm3
ADD1 %xmm7, %xmm10
addsd %xmm6, %xmm11
mulsd ALPHA_I, %xmm2
movsd %xmm12, 0 * SIZE(YY)
movsd %xmm13, 1 * SIZE(YY)
addq INCY, YY
movsd %xmm10, 0 * SIZE(YY)
movsd %xmm11, 1 * SIZE(YY)
addq INCY, YY
ALIGN_3
.L25:
movq M, %rax
andq $2, %rax
jle .L27
movsd 0 * SIZE(X), %xmm0
movsd 1 * SIZE(X), %xmm1
addq INCX, X
movsd 0 * SIZE(X), %xmm4
movsd 1 * SIZE(X), %xmm5
addq INCX, X
movaps %xmm0, %xmm2
movsd 0 * SIZE(Y), %xmm8
mulsd ALPHA_R, %xmm0
movaps %xmm1, %xmm3
movsd 1 * SIZE(Y), %xmm9
addq INCY, Y
mulsd ALPHA_R, %xmm1
movsd 0 * SIZE(Y), %xmm10
mulsd ALPHA_I, %xmm3
movsd 1 * SIZE(Y), %xmm11
mulsd ALPHA_I, %xmm2
addq INCY, Y
movaps %xmm4, %xmm6
mulsd ALPHA_R, %xmm4
addsd %xmm0, %xmm8
movaps %xmm5, %xmm7
mulsd ALPHA_R, %xmm5
ADD2 %xmm1, %xmm9
mulsd ALPHA_I, %xmm7
ADD1 %xmm3, %xmm8
mulsd ALPHA_I, %xmm6
addsd %xmm2, %xmm9
addsd %xmm4, %xmm10
movsd %xmm8, 0 * SIZE(YY)
ADD2 %xmm5, %xmm11
movsd %xmm9, 1 * SIZE(YY)
ADD1 %xmm7, %xmm10
addq INCY, YY
addsd %xmm6, %xmm11
movsd %xmm10, 0 * SIZE(YY)
movsd %xmm11, 1 * SIZE(YY)
addq INCY, YY
ALIGN_3
.L27:
movq M, %rax
andq $1, %rax
jle .L999
movsd 0 * SIZE(X), %xmm0
movsd 1 * SIZE(X), %xmm1
movsd 0 * SIZE(Y), %xmm8
movsd 1 * SIZE(Y), %xmm9
movaps %xmm0, %xmm2
mulsd ALPHA_R, %xmm0
movaps %xmm1, %xmm3
mulsd ALPHA_R, %xmm1
mulsd ALPHA_I, %xmm3
mulsd ALPHA_I, %xmm2
addsd %xmm0, %xmm8
ADD2 %xmm1, %xmm9
ADD1 %xmm3, %xmm8
addsd %xmm2, %xmm9
movsd %xmm8, 0 * SIZE(YY)
movsd %xmm9, 1 * SIZE(YY)
ALIGN_3
.L999:
xorq %rax, %rax
RESTOREREGISTERS
ret
EPILOGUE
|
