blob: 1885f845982360dfa65b3ffb630199166a5304a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
|
<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version='1.0'>
<!-- ********************************************************************
$Id$
********************************************************************
This file is part of the XSL DocBook Stylesheet distribution.
See ../README or http://nwalsh.com/docbook/xsl/ for copyright
and other information.
******************************************************************** -->
<!-- ==================================================================== -->
<xsl:template match="glossary">
<div class="{name(.)}">
<xsl:call-template name="component.separator"/>
<xsl:choose>
<xsl:when test="./title">
<xsl:apply-templates select="./title" mode="component.title.mode"/>
</xsl:when>
<xsl:otherwise>
<h2 class="title">
<a>
<xsl:attribute name="name">
<xsl:call-template name="object.id"/>
</xsl:attribute>
</a>
<xsl:call-template name="gentext.element.name"/>
</h2>
</xsl:otherwise>
</xsl:choose>
<xsl:if test="./subtitle">
<xsl:apply-templates select="./subtitle" mode="component.title.mode"/>
</xsl:if>
<dl>
<xsl:apply-templates/>
</dl>
<xsl:call-template name="process.footnotes"/>
</div>
</xsl:template>
<xsl:template match="glossary/glossaryinfo"></xsl:template>
<xsl:template match="glossary/title"></xsl:template>
<xsl:template match="glossary/subtitle"></xsl:template>
<xsl:template match="glossary/titleabbrev"></xsl:template>
<xsl:template match="glossary/title" mode="component.title.mode">
<h2>
<xsl:apply-templates/>
</h2>
</xsl:template>
<xsl:template match="glossary/subtitle" mode="component.title.mode">
<h3>
<i><xsl:apply-templates/></i>
</h3>
</xsl:template>
<!-- ==================================================================== -->
<xsl:template match="glosslist">
<div class="{name(.)}">
<a>
<xsl:attribute name="name">
<xsl:call-template name="object.id"/>
</xsl:attribute>
</a>
<dl>
<xsl:apply-templates/>
</dl>
</div>
</xsl:template>
<!-- ==================================================================== -->
<xsl:template match="glossdiv">
<div class="{name(.)}">
<xsl:apply-templates/>
</div>
</xsl:template>
<xsl:template match="glossdiv/title">
<h3 class="{name(.)}">
<xsl:apply-templates/>
</h3>
</xsl:template>
<!-- ==================================================================== -->
<!--
GlossEntry ::=
GlossTerm, Acronym?, Abbrev?,
(IndexTerm)*,
RevHistory?,
(GlossSee | GlossDef+)
-->
<xsl:template match="glossentry">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="glossentry/glossterm">
<dt>
<xsl:apply-templates/>
</dt>
</xsl:template>
<xsl:template match="glossentry/glossterm[1]" priority="2">
<dt>
<a>
<xsl:attribute name="name">
<xsl:call-template name="object.id">
<xsl:with-param name="object" select=".."/>
</xsl:call-template>
</xsl:attribute>
<xsl:apply-templates/>
</a>
</dt>
</xsl:template>
<xsl:template match="glossentry/acronym">
</xsl:template>
<xsl:template match="glossentry/abbrev">
</xsl:template>
<xsl:template match="glossentry/revhistory">
</xsl:template>
<xsl:template match="glossentry/glosssee">
<xsl:variable name="otherterm" select="@otherterm"/>
<xsl:variable name="targets" select="//node()[@id=$otherterm]"/>
<xsl:variable name="target" select="$targets[1]"/>
<dd>
<p>
<xsl:call-template name="gentext.element.name"/>
<xsl:call-template name="gentext.space"/>
<xsl:choose>
<xsl:when test="@otherterm">
<a href="#{@otherterm}">
<xsl:apply-templates select="$target" mode="xref"/>
</a>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates/>
</xsl:otherwise>
</xsl:choose>
<xsl:text>.</xsl:text>
</p>
</dd>
</xsl:template>
<xsl:template match="glossentry/glossdef">
<dd><xsl:apply-templates/></dd>
</xsl:template>
<xsl:template match="glossseealso">
<xsl:variable name="otherterm" select="@otherterm"/>
<xsl:variable name="targets" select="//node()[@id=$otherterm]"/>
<xsl:variable name="target" select="$targets[1]"/>
<p>
<xsl:call-template name="gentext.element.name"/>
<xsl:call-template name="gentext.space"/>
<xsl:choose>
<xsl:when test="@otherterm">
<a href="#{@otherterm}">
<xsl:apply-templates select="$target" mode="xref"/>
</a>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates/>
</xsl:otherwise>
</xsl:choose>
<xsl:text>.</xsl:text>
</p>
</xsl:template>
<!-- ==================================================================== -->
<xsl:template match="glossentry" mode="xref">
<xsl:apply-templates select="./glossterm[1]" mode="xref"/>
</xsl:template>
<xsl:template match="glossterm" mode="xref">
<xsl:apply-templates/>
</xsl:template>
<!-- ==================================================================== -->
</xsl:stylesheet>
|
