1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
|
*> \brief \b ZHET01_AA
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
* Definition:
* ===========
*
* SUBROUTINE ZHET01_AA( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV,
* C, LDC, RWORK, RESID )
*
* .. Scalar Arguments ..
* CHARACTER UPLO
* INTEGER LDA, LDAFAC, LDC, N
* COMPLEX*16 RESID
* ..
* .. Array Arguments ..
* INTEGER IPIV( * )
* COMPLEX*16 A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
* $ RWORK( * )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> ZHET01_AA reconstructs a hermitian indefinite matrix A from its
*> block L*D*L' or U*D*U' factorization and computes the residual
*> norm( C - A ) / ( N * norm(A) * EPS ),
*> where C is the reconstructed matrix and EPS is the machine epsilon.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] UPLO
*> \verbatim
*> UPLO is CHARACTER*1
*> Specifies whether the upper or lower triangular part of the
*> hermitian matrix A is stored:
*> = 'U': Upper triangular
*> = 'L': Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The number of rows and columns of the matrix A. N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*> A is COMPLEX*16 array, dimension (LDA,N)
*> The original hermitian matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> The leading dimension of the array A. LDA >= max(1,N)
*> \endverbatim
*>
*> \param[in] AFAC
*> \verbatim
*> AFAC is COMPLEX*16 array, dimension (LDAFAC,N)
*> The factored form of the matrix A. AFAC contains the block
*> diagonal matrix D and the multipliers used to obtain the
*> factor L or U from the block L*D*L' or U*D*U' factorization
*> as computed by ZHETRF.
*> \endverbatim
*>
*> \param[in] LDAFAC
*> \verbatim
*> LDAFAC is INTEGER
*> The leading dimension of the array AFAC. LDAFAC >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*> IPIV is INTEGER array, dimension (N)
*> The pivot indices from ZHETRF.
*> \endverbatim
*>
*> \param[out] C
*> \verbatim
*> C is COMPLEX*16 array, dimension (LDC,N)
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*> LDC is INTEGER
*> The leading dimension of the array C. LDC >= max(1,N).
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*> RWORK is COMPLEX*16 array, dimension (N)
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*> RESID is COMPLEX*16
*> If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
*> If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2016
*
*
*> \ingroup complex16_lin
*
* =====================================================================
SUBROUTINE ZHET01_AA( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C,
$ LDC, RWORK, RESID )
*
* -- LAPACK test routine (version 3.7.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2016
*
* .. Scalar Arguments ..
CHARACTER UPLO
INTEGER LDA, LDAFAC, LDC, N
DOUBLE PRECISION RESID
* ..
* .. Array Arguments ..
INTEGER IPIV( * )
COMPLEX*16 A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
$ RWORK( * )
* ..
*
* =====================================================================
*
* .. Parameters ..
COMPLEX*16 CZERO, CONE
PARAMETER ( CZERO = ( 0.0D+0, 0.0D+0 ),
$ CONE = ( 1.0D+0, 0.0D+0 ) )
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
* ..
* .. Local Scalars ..
INTEGER I, J
DOUBLE PRECISION ANORM, EPS
* ..
* .. External Functions ..
LOGICAL LSAME
DOUBLE PRECISION DLAMCH, ZLANHE
EXTERNAL LSAME, DLAMCH, ZLANHE
* ..
* .. External Subroutines ..
EXTERNAL ZLASET, ZLAVHE
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE
* ..
* .. Executable Statements ..
*
* Quick exit if N = 0.
*
IF( N.LE.0 ) THEN
RESID = ZERO
RETURN
END IF
*
* Determine EPS and the norm of A.
*
EPS = DLAMCH( 'Epsilon' )
ANORM = ZLANHE( '1', UPLO, N, A, LDA, RWORK )
*
* Initialize C to the tridiagonal matrix T.
*
CALL ZLASET( 'Full', N, N, CZERO, CZERO, C, LDC )
CALL ZLACPY( 'F', 1, N, AFAC( 1, 1 ), LDAFAC+1, C( 1, 1 ), LDC+1 )
IF( N.GT.1 ) THEN
IF( LSAME( UPLO, 'U' ) ) THEN
CALL ZLACPY( 'F', 1, N-1, AFAC( 1, 2 ), LDAFAC+1, C( 1, 2 ),
$ LDC+1 )
CALL ZLACPY( 'F', 1, N-1, AFAC( 1, 2 ), LDAFAC+1, C( 2, 1 ),
$ LDC+1 )
CALL ZLACGV( N-1, C( 2, 1 ), LDC+1 )
ELSE
CALL ZLACPY( 'F', 1, N-1, AFAC( 2, 1 ), LDAFAC+1, C( 1, 2 ),
$ LDC+1 )
CALL ZLACPY( 'F', 1, N-1, AFAC( 2, 1 ), LDAFAC+1, C( 2, 1 ),
$ LDC+1 )
CALL ZLACGV( N-1, C( 1, 2 ), LDC+1 )
ENDIF
ENDIF
*
* Call ZTRMM to form the product U' * D (or L * D ).
*
IF( LSAME( UPLO, 'U' ) ) THEN
CALL ZTRMM( 'Left', UPLO, 'Conjugate transpose', 'Unit', N-1,
$ N, CONE, AFAC( 1, 2 ), LDAFAC, C( 2, 1 ), LDC )
ELSE
CALL ZTRMM( 'Left', UPLO, 'No transpose', 'Unit', N-1, N,
$ CONE, AFAC( 2, 1 ), LDAFAC, C( 2, 1 ), LDC )
END IF
*
* Call ZTRMM again to multiply by U (or L ).
*
IF( LSAME( UPLO, 'U' ) ) THEN
CALL ZTRMM( 'Right', UPLO, 'No transpose', 'Unit', N, N-1,
$ CONE, AFAC( 1, 2 ), LDAFAC, C( 1, 2 ), LDC )
ELSE
CALL ZTRMM( 'Right', UPLO, 'Conjugate transpose', 'Unit', N,
$ N-1, CONE, AFAC( 2, 1 ), LDAFAC, C( 1, 2 ), LDC )
END IF
*
* Apply hermitian pivots
*
DO J = N, 1, -1
I = IPIV( J )
IF( I.NE.J )
$ CALL ZSWAP( N, C( J, 1 ), LDC, C( I, 1 ), LDC )
END DO
DO J = N, 1, -1
I = IPIV( J )
IF( I.NE.J )
$ CALL ZSWAP( N, C( 1, J ), 1, C( 1, I ), 1 )
END DO
*
*
* Compute the difference C - A .
*
IF( LSAME( UPLO, 'U' ) ) THEN
DO J = 1, N
DO I = 1, J
C( I, J ) = C( I, J ) - A( I, J )
END DO
END DO
ELSE
DO J = 1, N
DO I = J, N
C( I, J ) = C( I, J ) - A( I, J )
END DO
END DO
END IF
*
* Compute norm( C - A ) / ( N * norm(A) * EPS )
*
RESID = ZLANHE( '1', UPLO, N, C, LDC, RWORK )
*
IF( ANORM.LE.ZERO ) THEN
IF( RESID.NE.ZERO )
$ RESID = ONE / EPS
ELSE
RESID = ( ( RESID / DBLE( N ) ) / ANORM ) / EPS
END IF
*
RETURN
*
* End of ZHET01_AA
*
END
|
