1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
|
*> \brief \b ZHST01
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
* Definition:
* ===========
*
* SUBROUTINE ZHST01( N, ILO, IHI, A, LDA, H, LDH, Q, LDQ, WORK,
* LWORK, RWORK, RESULT )
*
* .. Scalar Arguments ..
* INTEGER IHI, ILO, LDA, LDH, LDQ, LWORK, N
* ..
* .. Array Arguments ..
* DOUBLE PRECISION RESULT( 2 ), RWORK( * )
* COMPLEX*16 A( LDA, * ), H( LDH, * ), Q( LDQ, * ),
* $ WORK( LWORK )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> ZHST01 tests the reduction of a general matrix A to upper Hessenberg
*> form: A = Q*H*Q'. Two test ratios are computed;
*>
*> RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
*> RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )
*>
*> The matrix Q is assumed to be given explicitly as it would be
*> following ZGEHRD + ZUNGHR.
*>
*> In this version, ILO and IHI are not used, but they could be used
*> to save some work if this is desired.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The order of the matrix A. N >= 0.
*> \endverbatim
*>
*> \param[in] ILO
*> \verbatim
*> ILO is INTEGER
*> \endverbatim
*>
*> \param[in] IHI
*> \verbatim
*> IHI is INTEGER
*>
*> A is assumed to be upper triangular in rows and columns
*> 1:ILO-1 and IHI+1:N, so Q differs from the identity only in
*> rows and columns ILO+1:IHI.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*> A is COMPLEX*16 array, dimension (LDA,N)
*> The original n by n matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> The leading dimension of the array A. LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] H
*> \verbatim
*> H is COMPLEX*16 array, dimension (LDH,N)
*> The upper Hessenberg matrix H from the reduction A = Q*H*Q'
*> as computed by ZGEHRD. H is assumed to be zero below the
*> first subdiagonal.
*> \endverbatim
*>
*> \param[in] LDH
*> \verbatim
*> LDH is INTEGER
*> The leading dimension of the array H. LDH >= max(1,N).
*> \endverbatim
*>
*> \param[in] Q
*> \verbatim
*> Q is COMPLEX*16 array, dimension (LDQ,N)
*> The orthogonal matrix Q from the reduction A = Q*H*Q' as
*> computed by ZGEHRD + ZUNGHR.
*> \endverbatim
*>
*> \param[in] LDQ
*> \verbatim
*> LDQ is INTEGER
*> The leading dimension of the array Q. LDQ >= max(1,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*> WORK is COMPLEX*16 array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*> LWORK is INTEGER
*> The length of the array WORK. LWORK >= 2*N*N.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*> RWORK is DOUBLE PRECISION array, dimension (N)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*> RESULT is DOUBLE PRECISION array, dimension (2)
*> RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
*> RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2011
*
*> \ingroup complex16_eig
*
* =====================================================================
SUBROUTINE ZHST01( N, ILO, IHI, A, LDA, H, LDH, Q, LDQ, WORK,
$ LWORK, RWORK, RESULT )
*
* -- LAPACK test routine (version 3.4.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2011
*
* .. Scalar Arguments ..
INTEGER IHI, ILO, LDA, LDH, LDQ, LWORK, N
* ..
* .. Array Arguments ..
DOUBLE PRECISION RESULT( 2 ), RWORK( * )
COMPLEX*16 A( LDA, * ), H( LDH, * ), Q( LDQ, * ),
$ WORK( LWORK )
* ..
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION ONE, ZERO
PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
* ..
* .. Local Scalars ..
INTEGER LDWORK
DOUBLE PRECISION ANORM, EPS, OVFL, SMLNUM, UNFL, WNORM
* ..
* .. External Functions ..
DOUBLE PRECISION DLAMCH, ZLANGE
EXTERNAL DLAMCH, ZLANGE
* ..
* .. External Subroutines ..
EXTERNAL DLABAD, ZGEMM, ZLACPY, ZUNT01
* ..
* .. Intrinsic Functions ..
INTRINSIC DCMPLX, MAX, MIN
* ..
* .. Executable Statements ..
*
* Quick return if possible
*
IF( N.LE.0 ) THEN
RESULT( 1 ) = ZERO
RESULT( 2 ) = ZERO
RETURN
END IF
*
UNFL = DLAMCH( 'Safe minimum' )
EPS = DLAMCH( 'Precision' )
OVFL = ONE / UNFL
CALL DLABAD( UNFL, OVFL )
SMLNUM = UNFL*N / EPS
*
* Test 1: Compute norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
*
* Copy A to WORK
*
LDWORK = MAX( 1, N )
CALL ZLACPY( ' ', N, N, A, LDA, WORK, LDWORK )
*
* Compute Q*H
*
CALL ZGEMM( 'No transpose', 'No transpose', N, N, N,
$ DCMPLX( ONE ), Q, LDQ, H, LDH, DCMPLX( ZERO ),
$ WORK( LDWORK*N+1 ), LDWORK )
*
* Compute A - Q*H*Q'
*
CALL ZGEMM( 'No transpose', 'Conjugate transpose', N, N, N,
$ DCMPLX( -ONE ), WORK( LDWORK*N+1 ), LDWORK, Q, LDQ,
$ DCMPLX( ONE ), WORK, LDWORK )
*
ANORM = MAX( ZLANGE( '1', N, N, A, LDA, RWORK ), UNFL )
WNORM = ZLANGE( '1', N, N, WORK, LDWORK, RWORK )
*
* Note that RESULT(1) cannot overflow and is bounded by 1/(N*EPS)
*
RESULT( 1 ) = MIN( WNORM, ANORM ) / MAX( SMLNUM, ANORM*EPS ) / N
*
* Test 2: Compute norm( I - Q'*Q ) / ( N * EPS )
*
CALL ZUNT01( 'Columns', N, N, Q, LDQ, WORK, LWORK, RWORK,
$ RESULT( 2 ) )
*
RETURN
*
* End of ZHST01
*
END
|
