1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
|
*> \brief \b DGQRTS
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
* Definition:
* ===========
*
* SUBROUTINE DGQRTS( N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
* BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
*
* .. Scalar Arguments ..
* INTEGER LDA, LDB, LWORK, M, N, P
* ..
* .. Array Arguments ..
* DOUBLE PRECISION A( LDA, * ), AF( LDA, * ), B( LDB, * ),
* $ BF( LDB, * ), BWK( LDB, * ), Q( LDA, * ),
* $ R( LDA, * ), RESULT( 4 ), RWORK( * ),
* $ T( LDB, * ), TAUA( * ), TAUB( * ),
* $ WORK( LWORK ), Z( LDB, * )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> DGQRTS tests DGGQRF, which computes the GQR factorization of an
*> N-by-M matrix A and a N-by-P matrix B: A = Q*R and B = Q*T*Z.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The number of rows of the matrices A and B. N >= 0.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*> M is INTEGER
*> The number of columns of the matrix A. M >= 0.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*> P is INTEGER
*> The number of columns of the matrix B. P >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*> A is DOUBLE PRECISION array, dimension (LDA,M)
*> The N-by-M matrix A.
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*> AF is DOUBLE PRECISION array, dimension (LDA,N)
*> Details of the GQR factorization of A and B, as returned
*> by DGGQRF, see SGGQRF for further details.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*> Q is DOUBLE PRECISION array, dimension (LDA,N)
*> The M-by-M orthogonal matrix Q.
*> \endverbatim
*>
*> \param[out] R
*> \verbatim
*> R is DOUBLE PRECISION array, dimension (LDA,MAX(M,N))
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> The leading dimension of the arrays A, AF, R and Q.
*> LDA >= max(M,N).
*> \endverbatim
*>
*> \param[out] TAUA
*> \verbatim
*> TAUA is DOUBLE PRECISION array, dimension (min(M,N))
*> The scalar factors of the elementary reflectors, as returned
*> by DGGQRF.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*> B is DOUBLE PRECISION array, dimension (LDB,P)
*> On entry, the N-by-P matrix A.
*> \endverbatim
*>
*> \param[out] BF
*> \verbatim
*> BF is DOUBLE PRECISION array, dimension (LDB,N)
*> Details of the GQR factorization of A and B, as returned
*> by DGGQRF, see SGGQRF for further details.
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*> Z is DOUBLE PRECISION array, dimension (LDB,P)
*> The P-by-P orthogonal matrix Z.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*> T is DOUBLE PRECISION array, dimension (LDB,max(P,N))
*> \endverbatim
*>
*> \param[out] BWK
*> \verbatim
*> BWK is DOUBLE PRECISION array, dimension (LDB,N)
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*> LDB is INTEGER
*> The leading dimension of the arrays B, BF, Z and T.
*> LDB >= max(P,N).
*> \endverbatim
*>
*> \param[out] TAUB
*> \verbatim
*> TAUB is DOUBLE PRECISION array, dimension (min(P,N))
*> The scalar factors of the elementary reflectors, as returned
*> by DGGRQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*> WORK is DOUBLE PRECISION array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*> LWORK is INTEGER
*> The dimension of the array WORK, LWORK >= max(N,M,P)**2.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*> RWORK is DOUBLE PRECISION array, dimension (max(N,M,P))
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*> RESULT is DOUBLE PRECISION array, dimension (4)
*> The test ratios:
*> RESULT(1) = norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP)
*> RESULT(2) = norm( T*Z - Q'*B ) / (MAX(P,N)*norm(B)*ULP)
*> RESULT(3) = norm( I - Q'*Q ) / ( M*ULP )
*> RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2011
*
*> \ingroup double_eig
*
* =====================================================================
SUBROUTINE DGQRTS( N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
$ BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
*
* -- LAPACK test routine (version 3.4.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2011
*
* .. Scalar Arguments ..
INTEGER LDA, LDB, LWORK, M, N, P
* ..
* .. Array Arguments ..
DOUBLE PRECISION A( LDA, * ), AF( LDA, * ), B( LDB, * ),
$ BF( LDB, * ), BWK( LDB, * ), Q( LDA, * ),
$ R( LDA, * ), RESULT( 4 ), RWORK( * ),
$ T( LDB, * ), TAUA( * ), TAUB( * ),
$ WORK( LWORK ), Z( LDB, * )
* ..
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
DOUBLE PRECISION ROGUE
PARAMETER ( ROGUE = -1.0D+10 )
* ..
* .. Local Scalars ..
INTEGER INFO
DOUBLE PRECISION ANORM, BNORM, RESID, ULP, UNFL
* ..
* .. External Functions ..
DOUBLE PRECISION DLAMCH, DLANGE, DLANSY
EXTERNAL DLAMCH, DLANGE, DLANSY
* ..
* .. External Subroutines ..
EXTERNAL DGEMM, DGGQRF, DLACPY, DLASET, DORGQR, DORGRQ,
$ DSYRK
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE, MAX, MIN
* ..
* .. Executable Statements ..
*
ULP = DLAMCH( 'Precision' )
UNFL = DLAMCH( 'Safe minimum' )
*
* Copy the matrix A to the array AF.
*
CALL DLACPY( 'Full', N, M, A, LDA, AF, LDA )
CALL DLACPY( 'Full', N, P, B, LDB, BF, LDB )
*
ANORM = MAX( DLANGE( '1', N, M, A, LDA, RWORK ), UNFL )
BNORM = MAX( DLANGE( '1', N, P, B, LDB, RWORK ), UNFL )
*
* Factorize the matrices A and B in the arrays AF and BF.
*
CALL DGGQRF( N, M, P, AF, LDA, TAUA, BF, LDB, TAUB, WORK, LWORK,
$ INFO )
*
* Generate the N-by-N matrix Q
*
CALL DLASET( 'Full', N, N, ROGUE, ROGUE, Q, LDA )
CALL DLACPY( 'Lower', N-1, M, AF( 2, 1 ), LDA, Q( 2, 1 ), LDA )
CALL DORGQR( N, N, MIN( N, M ), Q, LDA, TAUA, WORK, LWORK, INFO )
*
* Generate the P-by-P matrix Z
*
CALL DLASET( 'Full', P, P, ROGUE, ROGUE, Z, LDB )
IF( N.LE.P ) THEN
IF( N.GT.0 .AND. N.LT.P )
$ CALL DLACPY( 'Full', N, P-N, BF, LDB, Z( P-N+1, 1 ), LDB )
IF( N.GT.1 )
$ CALL DLACPY( 'Lower', N-1, N-1, BF( 2, P-N+1 ), LDB,
$ Z( P-N+2, P-N+1 ), LDB )
ELSE
IF( P.GT.1 )
$ CALL DLACPY( 'Lower', P-1, P-1, BF( N-P+2, 1 ), LDB,
$ Z( 2, 1 ), LDB )
END IF
CALL DORGRQ( P, P, MIN( N, P ), Z, LDB, TAUB, WORK, LWORK, INFO )
*
* Copy R
*
CALL DLASET( 'Full', N, M, ZERO, ZERO, R, LDA )
CALL DLACPY( 'Upper', N, M, AF, LDA, R, LDA )
*
* Copy T
*
CALL DLASET( 'Full', N, P, ZERO, ZERO, T, LDB )
IF( N.LE.P ) THEN
CALL DLACPY( 'Upper', N, N, BF( 1, P-N+1 ), LDB, T( 1, P-N+1 ),
$ LDB )
ELSE
CALL DLACPY( 'Full', N-P, P, BF, LDB, T, LDB )
CALL DLACPY( 'Upper', P, P, BF( N-P+1, 1 ), LDB, T( N-P+1, 1 ),
$ LDB )
END IF
*
* Compute R - Q'*A
*
CALL DGEMM( 'Transpose', 'No transpose', N, M, N, -ONE, Q, LDA, A,
$ LDA, ONE, R, LDA )
*
* Compute norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP ) .
*
RESID = DLANGE( '1', N, M, R, LDA, RWORK )
IF( ANORM.GT.ZERO ) THEN
RESULT( 1 ) = ( ( RESID / DBLE( MAX( 1, M, N ) ) ) / ANORM ) /
$ ULP
ELSE
RESULT( 1 ) = ZERO
END IF
*
* Compute T*Z - Q'*B
*
CALL DGEMM( 'No Transpose', 'No transpose', N, P, P, ONE, T, LDB,
$ Z, LDB, ZERO, BWK, LDB )
CALL DGEMM( 'Transpose', 'No transpose', N, P, N, -ONE, Q, LDA, B,
$ LDB, ONE, BWK, LDB )
*
* Compute norm( T*Z - Q'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
*
RESID = DLANGE( '1', N, P, BWK, LDB, RWORK )
IF( BNORM.GT.ZERO ) THEN
RESULT( 2 ) = ( ( RESID / DBLE( MAX( 1, P, N ) ) ) / BNORM ) /
$ ULP
ELSE
RESULT( 2 ) = ZERO
END IF
*
* Compute I - Q'*Q
*
CALL DLASET( 'Full', N, N, ZERO, ONE, R, LDA )
CALL DSYRK( 'Upper', 'Transpose', N, N, -ONE, Q, LDA, ONE, R,
$ LDA )
*
* Compute norm( I - Q'*Q ) / ( N * ULP ) .
*
RESID = DLANSY( '1', 'Upper', N, R, LDA, RWORK )
RESULT( 3 ) = ( RESID / DBLE( MAX( 1, N ) ) ) / ULP
*
* Compute I - Z'*Z
*
CALL DLASET( 'Full', P, P, ZERO, ONE, T, LDB )
CALL DSYRK( 'Upper', 'Transpose', P, P, -ONE, Z, LDB, ONE, T,
$ LDB )
*
* Compute norm( I - Z'*Z ) / ( P*ULP ) .
*
RESID = DLANSY( '1', 'Upper', P, T, LDB, RWORK )
RESULT( 4 ) = ( RESID / DBLE( MAX( 1, P ) ) ) / ULP
*
RETURN
*
* End of DGQRTS
*
END
|
