1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
|
*> \brief \b CGLMTS
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
* Definition:
* ===========
*
* SUBROUTINE CGLMTS( N, M, P, A, AF, LDA, B, BF, LDB, D, DF,
* X, U, WORK, LWORK, RWORK, RESULT )
*
* .. Scalar Arguments ..
* INTEGER LDA, LDB, LWORK, M, P, N
* REAL RESULT
* ..
* .. Array Arguments ..
* REAL RWORK( * )
* COMPLEX A( LDA, * ), AF( LDA, * ), B( LDB, * ),
* $ BF( LDB, * ), D( * ), DF( * ), U( * ),
* $ WORK( LWORK ), X( * )
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> CGLMTS tests CGGGLM - a subroutine for solving the generalized
*> linear model problem.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The number of rows of the matrices A and B. N >= 0.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*> M is INTEGER
*> The number of columns of the matrix A. M >= 0.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*> P is INTEGER
*> The number of columns of the matrix B. P >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*> A is COMPLEX array, dimension (LDA,M)
*> The N-by-M matrix A.
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*> AF is COMPLEX array, dimension (LDA,M)
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> The leading dimension of the arrays A, AF. LDA >= max(M,N).
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*> B is COMPLEX array, dimension (LDB,P)
*> The N-by-P matrix A.
*> \endverbatim
*>
*> \param[out] BF
*> \verbatim
*> BF is COMPLEX array, dimension (LDB,P)
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*> LDB is INTEGER
*> The leading dimension of the arrays B, BF. LDB >= max(P,N).
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*> D is COMPLEX array, dimension( N )
*> On input, the left hand side of the GLM.
*> \endverbatim
*>
*> \param[out] DF
*> \verbatim
*> DF is COMPLEX array, dimension( N )
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*> X is COMPLEX array, dimension( M )
*> solution vector X in the GLM problem.
*> \endverbatim
*>
*> \param[out] U
*> \verbatim
*> U is COMPLEX array, dimension( P )
*> solution vector U in the GLM problem.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*> WORK is COMPLEX array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*> LWORK is INTEGER
*> The dimension of the array WORK.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*> RWORK is REAL array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*> RESULT is REAL
*> The test ratio:
*> norm( d - A*x - B*u )
*> RESULT = -----------------------------------------
*> (norm(A)+norm(B))*(norm(x)+norm(u))*EPS
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2011
*
*> \ingroup complex_eig
*
* =====================================================================
SUBROUTINE CGLMTS( N, M, P, A, AF, LDA, B, BF, LDB, D, DF,
$ X, U, WORK, LWORK, RWORK, RESULT )
*
* -- LAPACK test routine (version 3.4.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2011
*
* .. Scalar Arguments ..
INTEGER LDA, LDB, LWORK, M, P, N
REAL RESULT
* ..
* .. Array Arguments ..
REAL RWORK( * )
COMPLEX A( LDA, * ), AF( LDA, * ), B( LDB, * ),
$ BF( LDB, * ), D( * ), DF( * ), U( * ),
$ WORK( LWORK ), X( * )
*
* ====================================================================
*
* .. Parameters ..
REAL ZERO
PARAMETER ( ZERO = 0.0E+0 )
COMPLEX CONE
PARAMETER ( CONE = 1.0E+0 )
* ..
* .. Local Scalars ..
INTEGER INFO
REAL ANORM, BNORM, EPS, XNORM, YNORM, DNORM, UNFL
* ..
* .. External Functions ..
REAL SCASUM, SLAMCH, CLANGE
EXTERNAL SCASUM, SLAMCH, CLANGE
* ..
* .. External Subroutines ..
EXTERNAL CLACPY
*
* .. Intrinsic Functions ..
INTRINSIC MAX
* ..
* .. Executable Statements ..
*
EPS = SLAMCH( 'Epsilon' )
UNFL = SLAMCH( 'Safe minimum' )
ANORM = MAX( CLANGE( '1', N, M, A, LDA, RWORK ), UNFL )
BNORM = MAX( CLANGE( '1', N, P, B, LDB, RWORK ), UNFL )
*
* Copy the matrices A and B to the arrays AF and BF,
* and the vector D the array DF.
*
CALL CLACPY( 'Full', N, M, A, LDA, AF, LDA )
CALL CLACPY( 'Full', N, P, B, LDB, BF, LDB )
CALL CCOPY( N, D, 1, DF, 1 )
*
* Solve GLM problem
*
CALL CGGGLM( N, M, P, AF, LDA, BF, LDB, DF, X, U, WORK, LWORK,
$ INFO )
*
* Test the residual for the solution of LSE
*
* norm( d - A*x - B*u )
* RESULT = -----------------------------------------
* (norm(A)+norm(B))*(norm(x)+norm(u))*EPS
*
CALL CCOPY( N, D, 1, DF, 1 )
CALL CGEMV( 'No transpose', N, M, -CONE, A, LDA, X, 1, CONE,
$ DF, 1 )
*
CALL CGEMV( 'No transpose', N, P, -CONE, B, LDB, U, 1, CONE,
$ DF, 1 )
*
DNORM = SCASUM( N, DF, 1 )
XNORM = SCASUM( M, X, 1 ) + SCASUM( P, U, 1 )
YNORM = ANORM + BNORM
*
IF( XNORM.LE.ZERO ) THEN
RESULT = ZERO
ELSE
RESULT = ( ( DNORM / YNORM ) / XNORM ) /EPS
END IF
*
RETURN
*
* End of CGLMTS
*
END
|
