1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
|
*> \brief \b STPQRT2 computes a QR factorization of a real or complex "triangular-pentagonal" matrix, which is composed of a triangular block and a pentagonal block, using the compact WY representation for Q.
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download STPQRT2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/stpqrt2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/stpqrt2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/stpqrt2.f">
*> [TXT]</a>
*> \endhtmlonly
*
* Definition:
* ===========
*
* SUBROUTINE STPQRT2( M, N, L, A, LDA, B, LDB, T, LDT, INFO )
*
* .. Scalar Arguments ..
* INTEGER INFO, LDA, LDB, LDT, N, M, L
* ..
* .. Array Arguments ..
* REAL A( LDA, * ), B( LDB, * ), T( LDT, * )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> STPQRT2 computes a QR factorization of a real "triangular-pentagonal"
*> matrix C, which is composed of a triangular block A and pentagonal block B,
*> using the compact WY representation for Q.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] M
*> \verbatim
*> M is INTEGER
*> The total number of rows of the matrix B.
*> M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The number of columns of the matrix B, and the order of
*> the triangular matrix A.
*> N >= 0.
*> \endverbatim
*>
*> \param[in] L
*> \verbatim
*> L is INTEGER
*> The number of rows of the upper trapezoidal part of B.
*> MIN(M,N) >= L >= 0. See Further Details.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*> A is REAL array, dimension (LDA,N)
*> On entry, the upper triangular N-by-N matrix A.
*> On exit, the elements on and above the diagonal of the array
*> contain the upper triangular matrix R.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> The leading dimension of the array A. LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*> B is REAL array, dimension (LDB,N)
*> On entry, the pentagonal M-by-N matrix B. The first M-L rows
*> are rectangular, and the last L rows are upper trapezoidal.
*> On exit, B contains the pentagonal matrix V. See Further Details.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*> LDB is INTEGER
*> The leading dimension of the array B. LDB >= max(1,M).
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*> T is REAL array, dimension (LDT,N)
*> The N-by-N upper triangular factor T of the block reflector.
*> See Further Details.
*> \endverbatim
*>
*> \param[in] LDT
*> \verbatim
*> LDT is INTEGER
*> The leading dimension of the array T. LDT >= max(1,N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*> INFO is INTEGER
*> = 0: successful exit
*> < 0: if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup realOTHERcomputational
*
*> \par Further Details:
* =====================
*>
*> \verbatim
*>
*> The input matrix C is a (N+M)-by-N matrix
*>
*> C = [ A ]
*> [ B ]
*>
*> where A is an upper triangular N-by-N matrix, and B is M-by-N pentagonal
*> matrix consisting of a (M-L)-by-N rectangular matrix B1 on top of a L-by-N
*> upper trapezoidal matrix B2:
*>
*> B = [ B1 ] <- (M-L)-by-N rectangular
*> [ B2 ] <- L-by-N upper trapezoidal.
*>
*> The upper trapezoidal matrix B2 consists of the first L rows of a
*> N-by-N upper triangular matrix, where 0 <= L <= MIN(M,N). If L=0,
*> B is rectangular M-by-N; if M=L=N, B is upper triangular.
*>
*> The matrix W stores the elementary reflectors H(i) in the i-th column
*> below the diagonal (of A) in the (N+M)-by-N input matrix C
*>
*> C = [ A ] <- upper triangular N-by-N
*> [ B ] <- M-by-N pentagonal
*>
*> so that W can be represented as
*>
*> W = [ I ] <- identity, N-by-N
*> [ V ] <- M-by-N, same form as B.
*>
*> Thus, all of information needed for W is contained on exit in B, which
*> we call V above. Note that V has the same form as B; that is,
*>
*> V = [ V1 ] <- (M-L)-by-N rectangular
*> [ V2 ] <- L-by-N upper trapezoidal.
*>
*> The columns of V represent the vectors which define the H(i)'s.
*> The (M+N)-by-(M+N) block reflector H is then given by
*>
*> H = I - W * T * W^H
*>
*> where W^H is the conjugate transpose of W and T is the upper triangular
*> factor of the block reflector.
*> \endverbatim
*>
* =====================================================================
SUBROUTINE STPQRT2( M, N, L, A, LDA, B, LDB, T, LDT, INFO )
*
* -- LAPACK computational routine (version 3.7.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* December 2016
*
* .. Scalar Arguments ..
INTEGER INFO, LDA, LDB, LDT, N, M, L
* ..
* .. Array Arguments ..
REAL A( LDA, * ), B( LDB, * ), T( LDT, * )
* ..
*
* =====================================================================
*
* .. Parameters ..
REAL ONE, ZERO
PARAMETER( ONE = 1.0, ZERO = 0.0 )
* ..
* .. Local Scalars ..
INTEGER I, J, P, MP, NP
REAL ALPHA
* ..
* .. External Subroutines ..
EXTERNAL SLARFG, SGEMV, SGER, STRMV, XERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX, MIN
* ..
* .. Executable Statements ..
*
* Test the input arguments
*
INFO = 0
IF( M.LT.0 ) THEN
INFO = -1
ELSE IF( N.LT.0 ) THEN
INFO = -2
ELSE IF( L.LT.0 .OR. L.GT.MIN(M,N) ) THEN
INFO = -3
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
INFO = -5
ELSE IF( LDB.LT.MAX( 1, M ) ) THEN
INFO = -7
ELSE IF( LDT.LT.MAX( 1, N ) ) THEN
INFO = -9
END IF
IF( INFO.NE.0 ) THEN
CALL XERBLA( 'STPQRT2', -INFO )
RETURN
END IF
*
* Quick return if possible
*
IF( N.EQ.0 .OR. M.EQ.0 ) RETURN
*
DO I = 1, N
*
* Generate elementary reflector H(I) to annihilate B(:,I)
*
P = M-L+MIN( L, I )
CALL SLARFG( P+1, A( I, I ), B( 1, I ), 1, T( I, 1 ) )
IF( I.LT.N ) THEN
*
* W(1:N-I) := C(I:M,I+1:N)^H * C(I:M,I) [use W = T(:,N)]
*
DO J = 1, N-I
T( J, N ) = (A( I, I+J ))
END DO
CALL SGEMV( 'T', P, N-I, ONE, B( 1, I+1 ), LDB,
$ B( 1, I ), 1, ONE, T( 1, N ), 1 )
*
* C(I:M,I+1:N) = C(I:m,I+1:N) + alpha*C(I:M,I)*W(1:N-1)^H
*
ALPHA = -(T( I, 1 ))
DO J = 1, N-I
A( I, I+J ) = A( I, I+J ) + ALPHA*(T( J, N ))
END DO
CALL SGER( P, N-I, ALPHA, B( 1, I ), 1,
$ T( 1, N ), 1, B( 1, I+1 ), LDB )
END IF
END DO
*
DO I = 2, N
*
* T(1:I-1,I) := C(I:M,1:I-1)^H * (alpha * C(I:M,I))
*
ALPHA = -T( I, 1 )
DO J = 1, I-1
T( J, I ) = ZERO
END DO
P = MIN( I-1, L )
MP = MIN( M-L+1, M )
NP = MIN( P+1, N )
*
* Triangular part of B2
*
DO J = 1, P
T( J, I ) = ALPHA*B( M-L+J, I )
END DO
CALL STRMV( 'U', 'T', 'N', P, B( MP, 1 ), LDB,
$ T( 1, I ), 1 )
*
* Rectangular part of B2
*
CALL SGEMV( 'T', L, I-1-P, ALPHA, B( MP, NP ), LDB,
$ B( MP, I ), 1, ZERO, T( NP, I ), 1 )
*
* B1
*
CALL SGEMV( 'T', M-L, I-1, ALPHA, B, LDB, B( 1, I ), 1,
$ ONE, T( 1, I ), 1 )
*
* T(1:I-1,I) := T(1:I-1,1:I-1) * T(1:I-1,I)
*
CALL STRMV( 'U', 'N', 'N', I-1, T, LDT, T( 1, I ), 1 )
*
* T(I,I) = tau(I)
*
T( I, I ) = T( I, 1 )
T( I, 1 ) = ZERO
END DO
*
* End of STPQRT2
*
END
|
