1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
|
*> \brief \b SSYEQUB
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download SSYEQUB + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ssyequb.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ssyequb.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ssyequb.f">
*> [TXT]</a>
*> \endhtmlonly
*
* Definition:
* ===========
*
* SUBROUTINE SSYEQUB( UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO )
*
* .. Scalar Arguments ..
* INTEGER INFO, LDA, N
* REAL AMAX, SCOND
* CHARACTER UPLO
* ..
* .. Array Arguments ..
* REAL A( LDA, * ), S( * ), WORK( * )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> SSYEQUB computes row and column scalings intended to equilibrate a
*> symmetric matrix A (with respect to the Euclidean norm) and reduce
*> its condition number. The scale factors S are computed by the BIN
*> algorithm (see references) so that the scaled matrix B with elements
*> B(i,j) = S(i)*A(i,j)*S(j) has a condition number within a factor N of
*> the smallest possible condition number over all possible diagonal
*> scalings.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] UPLO
*> \verbatim
*> UPLO is CHARACTER*1
*> = 'U': Upper triangle of A is stored;
*> = 'L': Lower triangle of A is stored.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The order of the matrix A. N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*> A is REAL array, dimension (LDA,N)
*> The N-by-N symmetric matrix whose scaling factors are to be
*> computed.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> The leading dimension of the array A. LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*> S is REAL array, dimension (N)
*> If INFO = 0, S contains the scale factors for A.
*> \endverbatim
*>
*> \param[out] SCOND
*> \verbatim
*> SCOND is REAL
*> If INFO = 0, S contains the ratio of the smallest S(i) to
*> the largest S(i). If SCOND >= 0.1 and AMAX is neither too
*> large nor too small, it is not worth scaling by S.
*> \endverbatim
*>
*> \param[out] AMAX
*> \verbatim
*> AMAX is REAL
*> Largest absolute value of any matrix element. If AMAX is
*> very close to overflow or very close to underflow, the
*> matrix should be scaled.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*> WORK is REAL array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*> INFO is INTEGER
*> = 0: successful exit
*> < 0: if INFO = -i, the i-th argument had an illegal value
*> > 0: if INFO = i, the i-th diagonal element is nonpositive.
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2011
*
*> \ingroup realSYcomputational
*
*> \par References:
* ================
*>
*> Livne, O.E. and Golub, G.H., "Scaling by Binormalization", \n
*> Numerical Algorithms, vol. 35, no. 1, pp. 97-120, January 2004. \n
*> DOI 10.1023/B:NUMA.0000016606.32820.69 \n
*> Tech report version: http://citeseerx.ist.psu.edu/viewdoc/summary?doi=10.1.1.3.1679
*>
* =====================================================================
SUBROUTINE SSYEQUB( UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO )
*
* -- LAPACK computational routine (version 3.4.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2011
*
* .. Scalar Arguments ..
INTEGER INFO, LDA, N
REAL AMAX, SCOND
CHARACTER UPLO
* ..
* .. Array Arguments ..
REAL A( LDA, * ), S( * ), WORK( * )
* ..
*
* =====================================================================
*
* .. Parameters ..
REAL ONE, ZERO
PARAMETER ( ONE = 1.0E0, ZERO = 0.0E0 )
INTEGER MAX_ITER
PARAMETER ( MAX_ITER = 100 )
* ..
* .. Local Scalars ..
INTEGER I, J, ITER
REAL AVG, STD, TOL, C0, C1, C2, T, U, SI, D, BASE,
$ SMIN, SMAX, SMLNUM, BIGNUM, SCALE, SUMSQ
LOGICAL UP
* ..
* .. External Functions ..
REAL SLAMCH
LOGICAL LSAME
EXTERNAL LSAME, SLAMCH
* ..
* .. External Subroutines ..
EXTERNAL SLASSQ
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, INT, LOG, MAX, MIN, SQRT
* ..
* .. Executable Statements ..
*
* Test the input parameters.
*
INFO = 0
IF ( .NOT. ( LSAME( UPLO, 'U' ) .OR. LSAME( UPLO, 'L' ) ) ) THEN
INFO = -1
ELSE IF ( N .LT. 0 ) THEN
INFO = -2
ELSE IF ( LDA .LT. MAX( 1, N ) ) THEN
INFO = -4
END IF
IF ( INFO .NE. 0 ) THEN
CALL XERBLA( 'SSYEQUB', -INFO )
RETURN
END IF
UP = LSAME( UPLO, 'U' )
AMAX = ZERO
*
* Quick return if possible.
*
IF ( N .EQ. 0 ) THEN
SCOND = ONE
RETURN
END IF
DO I = 1, N
S( I ) = ZERO
END DO
AMAX = ZERO
IF ( UP ) THEN
DO J = 1, N
DO I = 1, J-1
S( I ) = MAX( S( I ), ABS( A( I, J ) ) )
S( J ) = MAX( S( J ), ABS( A( I, J ) ) )
AMAX = MAX( AMAX, ABS( A( I, J ) ) )
END DO
S( J ) = MAX( S( J ), ABS( A( J, J ) ) )
AMAX = MAX( AMAX, ABS( A( J, J ) ) )
END DO
ELSE
DO J = 1, N
S( J ) = MAX( S( J ), ABS( A( J, J ) ) )
AMAX = MAX( AMAX, ABS( A( J, J ) ) )
DO I = J+1, N
S( I ) = MAX( S( I ), ABS( A( I, J ) ) )
S( J ) = MAX( S( J ), ABS( A( I, J ) ) )
AMAX = MAX( AMAX, ABS( A( I, J ) ) )
END DO
END DO
END IF
DO J = 1, N
S( J ) = 1.0E0 / S( J )
END DO
TOL = ONE / SQRT( 2.0E0 * N )
DO ITER = 1, MAX_ITER
SCALE = 0.0E0
SUMSQ = 0.0E0
* beta = |A|s
DO I = 1, N
WORK( I ) = ZERO
END DO
IF ( UP ) THEN
DO J = 1, N
DO I = 1, J-1
WORK( I ) = WORK( I ) + ABS( A( I, J ) ) * S( J )
WORK( J ) = WORK( J ) + ABS( A( I, J ) ) * S( I )
END DO
WORK( J ) = WORK( J ) + ABS( A( J, J ) ) * S( J )
END DO
ELSE
DO J = 1, N
WORK( J ) = WORK( J ) + ABS( A( J, J ) ) * S( J )
DO I = J+1, N
WORK( I ) = WORK( I ) + ABS( A( I, J ) ) * S( J )
WORK( J ) = WORK( J ) + ABS( A( I, J ) ) * S( I )
END DO
END DO
END IF
* avg = s^T beta / n
AVG = 0.0E0
DO I = 1, N
AVG = AVG + S( I )*WORK( I )
END DO
AVG = AVG / N
STD = 0.0E0
DO I = N+1, 2*N
WORK( I ) = S( I-N ) * WORK( I-N ) - AVG
END DO
CALL SLASSQ( N, WORK( N+1 ), 1, SCALE, SUMSQ )
STD = SCALE * SQRT( SUMSQ / N )
IF ( STD .LT. TOL * AVG ) GOTO 999
DO I = 1, N
T = ABS( A( I, I ) )
SI = S( I )
C2 = ( N-1 ) * T
C1 = ( N-2 ) * ( WORK( I ) - T*SI )
C0 = -(T*SI)*SI + 2*WORK( I )*SI - N*AVG
D = C1*C1 - 4*C0*C2
IF ( D .LE. 0 ) THEN
INFO = -1
RETURN
END IF
SI = -2*C0 / ( C1 + SQRT( D ) )
D = SI - S( I )
U = ZERO
IF ( UP ) THEN
DO J = 1, I
T = ABS( A( J, I ) )
U = U + S( J )*T
WORK( J ) = WORK( J ) + D*T
END DO
DO J = I+1,N
T = ABS( A( I, J ) )
U = U + S( J )*T
WORK( J ) = WORK( J ) + D*T
END DO
ELSE
DO J = 1, I
T = ABS( A( I, J ) )
U = U + S( J )*T
WORK( J ) = WORK( J ) + D*T
END DO
DO J = I+1,N
T = ABS( A( J, I ) )
U = U + S( J )*T
WORK( J ) = WORK( J ) + D*T
END DO
END IF
AVG = AVG + ( U + WORK( I ) ) * D / N
S( I ) = SI
END DO
END DO
999 CONTINUE
SMLNUM = SLAMCH( 'SAFEMIN' )
BIGNUM = ONE / SMLNUM
SMIN = BIGNUM
SMAX = ZERO
T = ONE / SQRT( AVG )
BASE = SLAMCH( 'B' )
U = ONE / LOG( BASE )
DO I = 1, N
S( I ) = BASE ** INT( U * LOG( S( I ) * T ) )
SMIN = MIN( SMIN, S( I ) )
SMAX = MAX( SMAX, S( I ) )
END DO
SCOND = MAX( SMIN, SMLNUM ) / MIN( SMAX, BIGNUM )
*
END
|
