blob: bfb01dbb7532ec7873982323b884fe22796b5f61 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
@if not defined _echo @echo off
setlocal
set rid=win10-x64
:Arg_Loop
if "%1" == "" goto ArgsDone
if /i "%1" == "-?" goto Usage
if /i "%1" == "-h" goto Usage
if /i "%1" == "-help" goto Usage
if /i "%1" == "clone" (set doClone=1&shift&goto Arg_Loop)
if /i "%1" == "setenv" (set setEnv=1&shift&goto Arg_Loop)
if /i "%1" == "x64" (set rid=win10-x64&shift&goto Arg_Loop)
if /i "%1" == "x86" (set rid=win10-x86&shift&goto Arg_Loop)
goto Usage
:ArgsDone
if defined doCLone (
git clone --recursive https://github.com/mono/linker
)
pushd linker\corebuild
call restore.cmd -RuntimeIdentifier=%rid%
set DoNotEmbedDescriptors=1
cd ..\linker
..\corebuild\Tools\dotnetcli\dotnet.exe publish -r %rid% -c netcore_Relase
popd
if not defined setEnv goto Done
echo set ILLINK=%cd%\linker\linker\bin\netcore_Relase\netcoreapp2.0\%rid%\publish\illink.exe
endlocal && set ILLINK=%cd%\linker\linker\bin\netcore_Relase\netcoreapp2.0\%rid%\publish\illink.exe
:Done
exit /b 0
:Usage
echo.
echo.Build the ILLINK for CoreCLR testing
echo.
echo.Usage:
echo build_illink.cmd [clone] [setenv] runtime-ID
echo.Where:
echo.-? -h -help: view this message.
echo.clone: Clone the repository https://github.com/mono/linker
echo.set: set ILLINK to the path to illink.exe
echo.runtime-ID: The os-architecture configuration to build: x64 (default) or x86
goto Done
|
