gcc/

2010-09-03  Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>

	    * configure.ac: Use the GCC_AC_ENABLE_DECIMAL_FLOAT macro.
	    * Makefile.in: Add aclocal.m4 dependency to dfp.m4.
	    * configure: Regenerate.
	    * aclocal.m4: Regenerate.

config/

2010-09-03  Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>

	    * dfp.m4: New file.

libdecnumber/

2010-09-03  Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>

	    * configure.ac: Use the GCC_AC_ENABLE_DECIMAL_FLOAT macro.
	    * Makefile.in: Add aclocal.m4 dependency to dfp.m4.
	    * configure: Regenerate.
	    * aclocal.m4: Regenerate.

libgcc/

2010-09-03  Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>

	    * configure.ac: Use the GCC_AC_ENABLE_DECIMAL_FLOAT macro.
	    Include dfp.m4.
	    * configure: Regenerate.



git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@163815 138bc75d-0d04-0410-961f-82ee72b054a4

11 files changed, 85 insertions, 114 deletions

diff --git a/config/ChangeLog b/config/ChangeLog
index 40e51f15212..cc20f81233d 100644
--- a/config/ChangeLog
+++ b/config/ChangeLog
@@ -1,3 +1,7 @@
+2010-09-03  Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>
+
+	* dfp.m4: New file.
+
 2010-09-01  Andi Kleen	<ak@linux.intel.com>
 
 	* bootstrap-lto.mk (STAGE2_CFLAGS, STAGE3_CFLAGS): Change
diff --git a/config/dfp.m4 b/config/dfp.m4
new file mode 100644
index 00000000000..4cace763fa4
--- /dev/null
+++ b/config/dfp.m4
@@ -0,0 +1,53 @@
+dnl @synopsis GCC_AC_ENABLE_DECIMAL_FLOAT([target triplet])
+dnl
+dnl Enable C extension for decimal float if target supports it.
+dnl
+dnl @author Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>
+
+AC_DEFUN([GCC_AC_ENABLE_DECIMAL_FLOAT],
+[
+AC_ARG_ENABLE(decimal-float,
+[  --enable-decimal-float={no,yes,bid,dpd}
+			enable decimal float extension to C.  Selecting 'bid'
+			or 'dpd' choses which decimal floating point format
+			to use],
+[
+  case $enable_decimal_float in
+    yes | no | bid | dpd) ;;
+    *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
+Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
+  esac
+],
+[
+  case $1 in
+    powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux* | s390*-*-linux*)
+      enable_decimal_float=yes
+      ;;
+    *)
+      AC_MSG_WARN(decimal float is not supported for this target, ignored)
+      enable_decimal_float=no
+      ;;
+  esac
+])
+
+# x86's use BID format instead of DPD
+case x$enable_decimal_float in
+  xyes)
+    case $1 in
+      i?86*-*-* | x86_64*-*-*)
+	enable_decimal_float=bid
+	;;
+      *)
+	enable_decimal_float=dpd
+	;;
+    esac
+    ;;
+  xno)
+    # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
+    # dependency on libdecnumber.
+    enable_decimal_float=dpd
+    ;;
+esac
+AC_SUBST(enable_decimal_float)
+
+])
\ No newline at end of file
diff --git a/gcc/ChangeLog b/gcc/ChangeLog
index cf3a172ea66..d64260d98c1 100644
--- a/gcc/ChangeLog
+++ b/gcc/ChangeLog
@@ -1,3 +1,10 @@
+2010-09-03  Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>
+
+	* configure.ac: Use the GCC_AC_ENABLE_DECIMAL_FLOAT macro.
+	* Makefile.in: Add aclocal.m4 dependency to dfp.m4.
+	* configure: Regenerate.
+	* aclocal.m4: Regenerate.
+
 2010-09-03  Jan Hubicka  <jh@suse.cz>
 
 	PR lto/44812
diff --git a/gcc/Makefile.in b/gcc/Makefile.in
index 61c5ddd1a24..3a34064999c 100644
--- a/gcc/Makefile.in
+++ b/gcc/Makefile.in
@@ -1712,6 +1712,7 @@ aclocal_deps = \
         $(srcdir)/../config/stdint.m4 \
 	$(srcdir)/../config/unwind_ipinfo.m4 \
 	$(srcdir)/../config/warnings.m4 \
+	$(srcdir)/../config/dfp.m4 \
 	$(srcdir)/acinclude.m4
 
 $(srcdir)/configure: @MAINT@ $(srcdir)/configure.ac $(srcdir)/aclocal.m4
diff --git a/gcc/configure.ac b/gcc/configure.ac
index 33086671d80..bbcbc7fdcf5 100644
--- a/gcc/configure.ac
+++ b/gcc/configure.ac
@@ -606,54 +606,12 @@ AC_ARG_ENABLE(__cxa_atexit,
 [], [])
 
 # Enable C extension for decimal float if target supports it.
-AC_ARG_ENABLE(decimal-float,
-[  --enable-decimal-float={no,yes,bid,dpd}
-			enable decimal float extension to C.  Selecting 'bid'
-			or 'dpd' choses which decimal floating point format
-			to use],
-[
-  case $enable_decimal_float in
-    yes | no | bid | dpd) ;;
-    *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
-Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
-  esac
-],
-[
-  case $target in
-    powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
-      enable_decimal_float=yes
-      ;;
-    *)
-      AC_MSG_WARN(decimal float is not supported for this target, ignored)
-      enable_decimal_float=no
-      ;;
-  esac
-])
+GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 
 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 [Define to 1 to enable decimal float extension to C.])
 
-# x86's use BID format instead of DPD
-case x$enable_decimal_float in
-  xyes)
-    case $target in
-      i?86*-*-linux* | x86_64*-*-linux*)
-	enable_decimal_float=bid
-	;;
-      *)
-	enable_decimal_float=dpd
-	;;
-    esac
-    ;;
-  xno)
-    # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
-    # dependency on libdecnumber.
-    enable_decimal_float=dpd
-    ;;
-esac
-AC_SUBST(enable_decimal_float)
-
 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 [Define to 1 to specify that we are using the BID decimal floating
diff --git a/libdecnumber/ChangeLog b/libdecnumber/ChangeLog
index 9ea1ed70c4e..b7952d08968 100644
--- a/libdecnumber/ChangeLog
+++ b/libdecnumber/ChangeLog
@@ -1,3 +1,10 @@
+2010-09-03  Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>
+
+	* configure.ac: Use the GCC_AC_ENABLE_DECIMAL_FLOAT macro.
+	* Makefile.in: Add aclocal.m4 dependency to dfp.m4.
+	* configure: Regenerate.
+	* aclocal.m4: Regenerate.
+
 2010-08-21  Ralf Wildenhues  <Ralf.Wildenhues@gmx.de>
 
 	* configure: Regenerate.
diff --git a/libdecnumber/Makefile.in b/libdecnumber/Makefile.in
index de91f6f614b..6424c3857de 100644
--- a/libdecnumber/Makefile.in
+++ b/libdecnumber/Makefile.in
@@ -98,6 +98,7 @@ aclocal_deps = \
 	$(srcdir)/../config/stdint.m4 \
 	$(srcdir)/../config/warnings.m4 \
 	$(srcdir)/../config/override.m4 \
+	$(srcdir)/../config/dfp.m4 \
 	$(srcdir)/configure.ac
 
 $(srcdir)/aclocal.m4: @MAINT@ $(aclocal_deps)
diff --git a/libdecnumber/configure.ac b/libdecnumber/configure.ac
index 4d9060f5cd5..a4cbf55f1a4 100644
--- a/libdecnumber/configure.ac
+++ b/libdecnumber/configure.ac
@@ -75,42 +75,8 @@ AC_CANONICAL_TARGET
 # Default decimal format
 # If you change the defaults here, be sure to change them in the GCC directory also
 AC_MSG_CHECKING([for decimal floating point])
-AC_ARG_ENABLE(decimal-float,
-[  --enable-decimal-float={no,yes,bid,dpd}
-			enable decimal float extension to C.  Selecting 'bid'
-			or 'dpd' choses which decimal floating point format
-			to use],
-[
-  case $enable_decimal_float in
-    yes | no | bid | dpd) ;;
-    *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
-Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
-  esac
-],
-[
-  case $target in
-    powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
-      enable_decimal_float=yes
-      ;;
-    *)
-      enable_decimal_float=no
-      ;;
-  esac
-])
-
-# x86's use BID format instead of DPD
-# In theory --enable-decimal-float=no should not compile anything
-# For the sake of simplicity, just use the default format in this directory
-if test x$enable_decimal_float = xyes -o x$enable_decimal_float = xno; then
-  case $target in
-    i?86*-*-linux* | x86_64*-*-linux*)
-      enable_decimal_float=bid
-      ;;
-    *)
-      enable_decimal_float=dpd
-      ;;
-  esac
-fi
+
+GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 
 # If BID is being used, additional objects should be linked in.
 if test x$enable_decimal_float = xbid; then
diff --git a/libgcc/ChangeLog b/libgcc/ChangeLog
index d3bad75239a..bb5bc0fd5b3 100644
--- a/libgcc/ChangeLog
+++ b/libgcc/ChangeLog
@@ -1,3 +1,9 @@
+2010-09-03  Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>
+
+	* configure.ac: Use the GCC_AC_ENABLE_DECIMAL_FLOAT macro.
+	Include dfp.m4.
+	* configure: Regenerate.
+
 2010-09-01  Uros Bizjak  <ubizjak@gmail.com>
 
 	* config.host (i[34567]86-*-freebsd*, x86_64-*-freebsd*): Add
diff --git a/libgcc/Makefile.in b/libgcc/Makefile.in
index 080aae28707..044be7a49a1 100644
--- a/libgcc/Makefile.in
+++ b/libgcc/Makefile.in
@@ -147,6 +147,7 @@ configure_deps = \
 	$(srcdir)/../config/acx.m4 \
 	$(srcdir)/../config/no-executables.m4 \
 	$(srcdir)/../config/override.m4 \
+	$(srcdir)/../config/dfp.m4 \
 
 $(srcdir)/configure: @MAINT@ $(srcdir)/configure.ac $(configure_deps)
 	cd $(srcdir) && $(AUTOCONF)
diff --git a/libgcc/configure.ac b/libgcc/configure.ac
index ce467dda598..60766371d3a 100644
--- a/libgcc/configure.ac
+++ b/libgcc/configure.ac
@@ -5,6 +5,7 @@ sinclude(../config/tls.m4)
 sinclude(../config/acx.m4)
 sinclude(../config/no-executables.m4)
 sinclude(../config/override.m4)
+sinclude(../config/dfp.m4)
 
 AC_PREREQ(2.64)
 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
@@ -125,41 +126,7 @@ AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 decimal_float=$libgcc_cv_dfp
 AC_SUBST(decimal_float)
 
-AC_ARG_ENABLE(decimal-float,
-[  --enable-decimal-float={no,yes,bid,dpd}
-			enable decimal float extension to C.  Selecting 'bid'
-			or 'dpd' choses which decimal floating point format
-			to use],
-[
-  case $enable_decimal_float in
-    yes | no | bid | dpd) ;;
-    *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
-Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
-  esac
-],
-[
-  case $host in
-    powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
-      enable_decimal_float=yes
-      ;;
-    *)
-      enable_decimal_float=no
-      ;;
-  esac
-])
-
-# x86's use BID format instead of DPD
-if test x$enable_decimal_float = xyes; then
-  case $host in
-    i?86*-*-linux* | x86_64*-*-linux*)
-      enable_decimal_float=bid
-      ;;
-    *)
-      enable_decimal_float=dpd
-      ;;
-  esac
-fi
-AC_SUBST(enable_decimal_float)
+GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 
 # Check for fixed-point support.
 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],