1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
|
SUBROUTINE DTFTRI( TRANSR, UPLO, DIAG, N, A, INFO )
*
* -- LAPACK routine (version 3.2.1) --
*
* -- Contributed by Fred Gustavson of the IBM Watson Research Center --
* -- April 2009 --
*
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
* .. Scalar Arguments ..
CHARACTER TRANSR, UPLO, DIAG
INTEGER INFO, N
* ..
* .. Array Arguments ..
DOUBLE PRECISION A( 0: * )
* ..
*
* Purpose
* =======
*
* DTFTRI computes the inverse of a triangular matrix A stored in RFP
* format.
*
* This is a Level 3 BLAS version of the algorithm.
*
* Arguments
* =========
*
* TRANSR (input) CHARACTER
* = 'N': The Normal TRANSR of RFP A is stored;
* = 'T': The Transpose TRANSR of RFP A is stored.
*
* UPLO (input) CHARACTER
* = 'U': A is upper triangular;
* = 'L': A is lower triangular.
*
* DIAG (input) CHARACTER
* = 'N': A is non-unit triangular;
* = 'U': A is unit triangular.
*
* N (input) INTEGER
* The order of the matrix A. N >= 0.
*
* A (input/output) DOUBLE PRECISION array, dimension (0:nt-1);
* nt=N*(N+1)/2. On entry, the triangular factor of a Hermitian
* Positive Definite matrix A in RFP format. RFP format is
* described by TRANSR, UPLO, and N as follows: If TRANSR = 'N'
* then RFP A is (0:N,0:k-1) when N is even; k=N/2. RFP A is
* (0:N-1,0:k) when N is odd; k=N/2. IF TRANSR = 'T' then RFP is
* the transpose of RFP A as defined when
* TRANSR = 'N'. The contents of RFP A are defined by UPLO as
* follows: If UPLO = 'U' the RFP A contains the nt elements of
* upper packed A; If UPLO = 'L' the RFP A contains the nt
* elements of lower packed A. The LDA of RFP A is (N+1)/2 when
* TRANSR = 'T'. When TRANSR is 'N' the LDA is N+1 when N is
* even and N is odd. See the Note below for more details.
*
* On exit, the (triangular) inverse of the original matrix, in
* the same storage format.
*
* INFO (output) INTEGER
* = 0: successful exit
* < 0: if INFO = -i, the i-th argument had an illegal value
* > 0: if INFO = i, A(i,i) is exactly zero. The triangular
* matrix is singular and its inverse can not be computed.
*
* Further Details
* ===============
*
* We first consider Rectangular Full Packed (RFP) Format when N is
* even. We give an example where N = 6.
*
* AP is Upper AP is Lower
*
* 00 01 02 03 04 05 00
* 11 12 13 14 15 10 11
* 22 23 24 25 20 21 22
* 33 34 35 30 31 32 33
* 44 45 40 41 42 43 44
* 55 50 51 52 53 54 55
*
*
* Let TRANSR = 'N'. RFP holds AP as follows:
* For UPLO = 'U' the upper trapezoid A(0:5,0:2) consists of the last
* three columns of AP upper. The lower triangle A(4:6,0:2) consists of
* the transpose of the first three columns of AP upper.
* For UPLO = 'L' the lower trapezoid A(1:6,0:2) consists of the first
* three columns of AP lower. The upper triangle A(0:2,0:2) consists of
* the transpose of the last three columns of AP lower.
* This covers the case N even and TRANSR = 'N'.
*
* RFP A RFP A
*
* 03 04 05 33 43 53
* 13 14 15 00 44 54
* 23 24 25 10 11 55
* 33 34 35 20 21 22
* 00 44 45 30 31 32
* 01 11 55 40 41 42
* 02 12 22 50 51 52
*
* Now let TRANSR = 'T'. RFP A in both UPLO cases is just the
* transpose of RFP A above. One therefore gets:
*
*
* RFP A RFP A
*
* 03 13 23 33 00 01 02 33 00 10 20 30 40 50
* 04 14 24 34 44 11 12 43 44 11 21 31 41 51
* 05 15 25 35 45 55 22 53 54 55 22 32 42 52
*
*
* We first consider Rectangular Full Packed (RFP) Format when N is
* odd. We give an example where N = 5.
*
* AP is Upper AP is Lower
*
* 00 01 02 03 04 00
* 11 12 13 14 10 11
* 22 23 24 20 21 22
* 33 34 30 31 32 33
* 44 40 41 42 43 44
*
*
* Let TRANSR = 'N'. RFP holds AP as follows:
* For UPLO = 'U' the upper trapezoid A(0:4,0:2) consists of the last
* three columns of AP upper. The lower triangle A(3:4,0:1) consists of
* the transpose of the first two columns of AP upper.
* For UPLO = 'L' the lower trapezoid A(0:4,0:2) consists of the first
* three columns of AP lower. The upper triangle A(0:1,1:2) consists of
* the transpose of the last two columns of AP lower.
* This covers the case N odd and TRANSR = 'N'.
*
* RFP A RFP A
*
* 02 03 04 00 33 43
* 12 13 14 10 11 44
* 22 23 24 20 21 22
* 00 33 34 30 31 32
* 01 11 44 40 41 42
*
* Now let TRANSR = 'T'. RFP A in both UPLO cases is just the
* transpose of RFP A above. One therefore gets:
*
* RFP A RFP A
*
* 02 12 22 00 01 00 10 20 30 40 50
* 03 13 23 33 11 33 11 21 31 41 51
* 04 14 24 34 44 43 44 22 32 42 52
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION ONE
PARAMETER ( ONE = 1.0D+0 )
* ..
* .. Local Scalars ..
LOGICAL LOWER, NISODD, NORMALTRANSR
INTEGER N1, N2, K
* ..
* .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
* ..
* .. External Subroutines ..
EXTERNAL XERBLA, DTRMM, DTRTRI
* ..
* .. Intrinsic Functions ..
INTRINSIC MOD
* ..
* .. Executable Statements ..
*
* Test the input parameters.
*
INFO = 0
NORMALTRANSR = LSAME( TRANSR, 'N' )
LOWER = LSAME( UPLO, 'L' )
IF( .NOT.NORMALTRANSR .AND. .NOT.LSAME( TRANSR, 'T' ) ) THEN
INFO = -1
ELSE IF( .NOT.LOWER .AND. .NOT.LSAME( UPLO, 'U' ) ) THEN
INFO = -2
ELSE IF( .NOT.LSAME( DIAG, 'N' ) .AND. .NOT.LSAME( DIAG, 'U' ) )
+ THEN
INFO = -3
ELSE IF( N.LT.0 ) THEN
INFO = -4
END IF
IF( INFO.NE.0 ) THEN
CALL XERBLA( 'DTFTRI', -INFO )
RETURN
END IF
*
* Quick return if possible
*
IF( N.EQ.0 )
+ RETURN
*
* If N is odd, set NISODD = .TRUE.
* If N is even, set K = N/2 and NISODD = .FALSE.
*
IF( MOD( N, 2 ).EQ.0 ) THEN
K = N / 2
NISODD = .FALSE.
ELSE
NISODD = .TRUE.
END IF
*
* Set N1 and N2 depending on LOWER
*
IF( LOWER ) THEN
N2 = N / 2
N1 = N - N2
ELSE
N1 = N / 2
N2 = N - N1
END IF
*
*
* start execution: there are eight cases
*
IF( NISODD ) THEN
*
* N is odd
*
IF( NORMALTRANSR ) THEN
*
* N is odd and TRANSR = 'N'
*
IF( LOWER ) THEN
*
* SRPA for LOWER, NORMAL and N is odd ( a(0:n-1,0:n1-1) )
* T1 -> a(0,0), T2 -> a(0,1), S -> a(n1,0)
* T1 -> a(0), T2 -> a(n), S -> a(n1)
*
CALL DTRTRI( 'L', DIAG, N1, A( 0 ), N, INFO )
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'R', 'L', 'N', DIAG, N2, N1, -ONE, A( 0 ),
+ N, A( N1 ), N )
CALL DTRTRI( 'U', DIAG, N2, A( N ), N, INFO )
IF( INFO.GT.0 )
+ INFO = INFO + N1
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'L', 'U', 'T', DIAG, N2, N1, ONE, A( N ), N,
+ A( N1 ), N )
*
ELSE
*
* SRPA for UPPER, NORMAL and N is odd ( a(0:n-1,0:n2-1)
* T1 -> a(n1+1,0), T2 -> a(n1,0), S -> a(0,0)
* T1 -> a(n2), T2 -> a(n1), S -> a(0)
*
CALL DTRTRI( 'L', DIAG, N1, A( N2 ), N, INFO )
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'L', 'L', 'T', DIAG, N1, N2, -ONE, A( N2 ),
+ N, A( 0 ), N )
CALL DTRTRI( 'U', DIAG, N2, A( N1 ), N, INFO )
IF( INFO.GT.0 )
+ INFO = INFO + N1
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'R', 'U', 'N', DIAG, N1, N2, ONE, A( N1 ),
+ N, A( 0 ), N )
*
END IF
*
ELSE
*
* N is odd and TRANSR = 'T'
*
IF( LOWER ) THEN
*
* SRPA for LOWER, TRANSPOSE and N is odd
* T1 -> a(0), T2 -> a(1), S -> a(0+n1*n1)
*
CALL DTRTRI( 'U', DIAG, N1, A( 0 ), N1, INFO )
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'L', 'U', 'N', DIAG, N1, N2, -ONE, A( 0 ),
+ N1, A( N1*N1 ), N1 )
CALL DTRTRI( 'L', DIAG, N2, A( 1 ), N1, INFO )
IF( INFO.GT.0 )
+ INFO = INFO + N1
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'R', 'L', 'T', DIAG, N1, N2, ONE, A( 1 ),
+ N1, A( N1*N1 ), N1 )
*
ELSE
*
* SRPA for UPPER, TRANSPOSE and N is odd
* T1 -> a(0+n2*n2), T2 -> a(0+n1*n2), S -> a(0)
*
CALL DTRTRI( 'U', DIAG, N1, A( N2*N2 ), N2, INFO )
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'R', 'U', 'T', DIAG, N2, N1, -ONE,
+ A( N2*N2 ), N2, A( 0 ), N2 )
CALL DTRTRI( 'L', DIAG, N2, A( N1*N2 ), N2, INFO )
IF( INFO.GT.0 )
+ INFO = INFO + N1
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'L', 'L', 'N', DIAG, N2, N1, ONE,
+ A( N1*N2 ), N2, A( 0 ), N2 )
END IF
*
END IF
*
ELSE
*
* N is even
*
IF( NORMALTRANSR ) THEN
*
* N is even and TRANSR = 'N'
*
IF( LOWER ) THEN
*
* SRPA for LOWER, NORMAL, and N is even ( a(0:n,0:k-1) )
* T1 -> a(1,0), T2 -> a(0,0), S -> a(k+1,0)
* T1 -> a(1), T2 -> a(0), S -> a(k+1)
*
CALL DTRTRI( 'L', DIAG, K, A( 1 ), N+1, INFO )
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'R', 'L', 'N', DIAG, K, K, -ONE, A( 1 ),
+ N+1, A( K+1 ), N+1 )
CALL DTRTRI( 'U', DIAG, K, A( 0 ), N+1, INFO )
IF( INFO.GT.0 )
+ INFO = INFO + K
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'L', 'U', 'T', DIAG, K, K, ONE, A( 0 ), N+1,
+ A( K+1 ), N+1 )
*
ELSE
*
* SRPA for UPPER, NORMAL, and N is even ( a(0:n,0:k-1) )
* T1 -> a(k+1,0) , T2 -> a(k,0), S -> a(0,0)
* T1 -> a(k+1), T2 -> a(k), S -> a(0)
*
CALL DTRTRI( 'L', DIAG, K, A( K+1 ), N+1, INFO )
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'L', 'L', 'T', DIAG, K, K, -ONE, A( K+1 ),
+ N+1, A( 0 ), N+1 )
CALL DTRTRI( 'U', DIAG, K, A( K ), N+1, INFO )
IF( INFO.GT.0 )
+ INFO = INFO + K
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'R', 'U', 'N', DIAG, K, K, ONE, A( K ), N+1,
+ A( 0 ), N+1 )
END IF
ELSE
*
* N is even and TRANSR = 'T'
*
IF( LOWER ) THEN
*
* SRPA for LOWER, TRANSPOSE and N is even (see paper)
* T1 -> B(0,1), T2 -> B(0,0), S -> B(0,k+1)
* T1 -> a(0+k), T2 -> a(0+0), S -> a(0+k*(k+1)); lda=k
*
CALL DTRTRI( 'U', DIAG, K, A( K ), K, INFO )
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'L', 'U', 'N', DIAG, K, K, -ONE, A( K ), K,
+ A( K*( K+1 ) ), K )
CALL DTRTRI( 'L', DIAG, K, A( 0 ), K, INFO )
IF( INFO.GT.0 )
+ INFO = INFO + K
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'R', 'L', 'T', DIAG, K, K, ONE, A( 0 ), K,
+ A( K*( K+1 ) ), K )
ELSE
*
* SRPA for UPPER, TRANSPOSE and N is even (see paper)
* T1 -> B(0,k+1), T2 -> B(0,k), S -> B(0,0)
* T1 -> a(0+k*(k+1)), T2 -> a(0+k*k), S -> a(0+0)); lda=k
*
CALL DTRTRI( 'U', DIAG, K, A( K*( K+1 ) ), K, INFO )
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'R', 'U', 'T', DIAG, K, K, -ONE,
+ A( K*( K+1 ) ), K, A( 0 ), K )
CALL DTRTRI( 'L', DIAG, K, A( K*K ), K, INFO )
IF( INFO.GT.0 )
+ INFO = INFO + K
IF( INFO.GT.0 )
+ RETURN
CALL DTRMM( 'L', 'L', 'N', DIAG, K, K, ONE, A( K*K ), K,
+ A( 0 ), K )
END IF
END IF
END IF
*
RETURN
*
* End of DTFTRI
*
END
|
