Move LAPACK trunk into position.

1 files changed, 215 insertions, 0 deletions

diff --git a/TESTING/LIN/cppt05.f b/TESTING/LIN/cppt05.f
new file mode 100644
index 00000000..8cf00f29
--- /dev/null
+++ b/TESTING/LIN/cppt05.f
@@ -0,0 +1,215 @@
+      SUBROUTINE CPPT05( UPLO, N, NRHS, AP, B, LDB, X, LDX, XACT,
+     $                   LDXACT, FERR, BERR, RESLTS )
+*
+*  -- LAPACK test routine (version 3.1) --
+*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
+*     November 2006
+*
+*     .. Scalar Arguments ..
+      CHARACTER          UPLO
+      INTEGER            LDB, LDX, LDXACT, N, NRHS
+*     ..
+*     .. Array Arguments ..
+      REAL               BERR( * ), FERR( * ), RESLTS( * )
+      COMPLEX            AP( * ), B( LDB, * ), X( LDX, * ),
+     $                   XACT( LDXACT, * )
+*     ..
+*
+*  Purpose
+*  =======
+*
+*  CPPT05 tests the error bounds from iterative refinement for the
+*  computed solution to a system of equations A*X = B, where A is a
+*  Hermitian matrix in packed storage format.
+*
+*  RESLTS(1) = test of the error bound
+*            = norm(X - XACT) / ( norm(X) * FERR )
+*
+*  A large value is returned if this ratio is not less than one.
+*
+*  RESLTS(2) = residual from the iterative refinement routine
+*            = the maximum of BERR / ( (n+1)*EPS + (*) ), where
+*              (*) = (n+1)*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
+*
+*  Arguments
+*  =========
+*
+*  UPLO    (input) CHARACTER*1
+*          Specifies whether the upper or lower triangular part of the
+*          Hermitian matrix A is stored.
+*          = 'U':  Upper triangular
+*          = 'L':  Lower triangular
+*
+*  N       (input) INTEGER
+*          The number of rows of the matrices X, B, and XACT, and the
+*          order of the matrix A.  N >= 0.
+*
+*  NRHS    (input) INTEGER
+*          The number of columns of the matrices X, B, and XACT.
+*          NRHS >= 0.
+*
+*  AP      (input) COMPLEX array, dimension (N*(N+1)/2)
+*          The upper or lower triangle of the Hermitian matrix A, packed
+*          columnwise in a linear array.  The j-th column of A is stored
+*          in the array AP as follows:
+*          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
+*          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
+*
+*  B       (input) COMPLEX array, dimension (LDB,NRHS)
+*          The right hand side vectors for the system of linear
+*          equations.
+*
+*  LDB     (input) INTEGER
+*          The leading dimension of the array B.  LDB >= max(1,N).
+*
+*  X       (input) COMPLEX array, dimension (LDX,NRHS)
+*          The computed solution vectors.  Each vector is stored as a
+*          column of the matrix X.
+*
+*  LDX     (input) INTEGER
+*          The leading dimension of the array X.  LDX >= max(1,N).
+*
+*  XACT    (input) COMPLEX array, dimension (LDX,NRHS)
+*          The exact solution vectors.  Each vector is stored as a
+*          column of the matrix XACT.
+*
+*  LDXACT  (input) INTEGER
+*          The leading dimension of the array XACT.  LDXACT >= max(1,N).
+*
+*  FERR    (input) REAL array, dimension (NRHS)
+*          The estimated forward error bounds for each solution vector
+*          X.  If XTRUE is the true solution, FERR bounds the magnitude
+*          of the largest entry in (X - XTRUE) divided by the magnitude
+*          of the largest entry in X.
+*
+*  BERR    (input) REAL array, dimension (NRHS)
+*          The componentwise relative backward error of each solution
+*          vector (i.e., the smallest relative change in any entry of A
+*          or B that makes X an exact solution).
+*
+*  RESLTS  (output) REAL array, dimension (2)
+*          The maximum over the NRHS solution vectors of the ratios:
+*          RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR )
+*          RESLTS(2) = BERR / ( (n+1)*EPS + (*) )
+*
+*  =====================================================================
+*
+*     .. Parameters ..
+      REAL               ZERO, ONE
+      PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
+*     ..
+*     .. Local Scalars ..
+      LOGICAL            UPPER
+      INTEGER            I, IMAX, J, JC, K
+      REAL               AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
+      COMPLEX            ZDUM
+*     ..
+*     .. External Functions ..
+      LOGICAL            LSAME
+      INTEGER            ICAMAX
+      REAL               SLAMCH
+      EXTERNAL           LSAME, ICAMAX, SLAMCH
+*     ..
+*     .. Intrinsic Functions ..
+      INTRINSIC          ABS, AIMAG, MAX, MIN, REAL
+*     ..
+*     .. Statement Functions ..
+      REAL               CABS1
+*     ..
+*     .. Statement Function definitions ..
+      CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
+*     ..
+*     .. Executable Statements ..
+*
+*     Quick exit if N = 0 or NRHS = 0.
+*
+      IF( N.LE.0 .OR. NRHS.LE.0 ) THEN
+         RESLTS( 1 ) = ZERO
+         RESLTS( 2 ) = ZERO
+         RETURN
+      END IF
+*
+      EPS = SLAMCH( 'Epsilon' )
+      UNFL = SLAMCH( 'Safe minimum' )
+      OVFL = ONE / UNFL
+      UPPER = LSAME( UPLO, 'U' )
+*
+*     Test 1:  Compute the maximum of
+*        norm(X - XACT) / ( norm(X) * FERR )
+*     over all the vectors X and XACT using the infinity-norm.
+*
+      ERRBND = ZERO
+      DO 30 J = 1, NRHS
+         IMAX = ICAMAX( N, X( 1, J ), 1 )
+         XNORM = MAX( CABS1( X( IMAX, J ) ), UNFL )
+         DIFF = ZERO
+         DO 10 I = 1, N
+            DIFF = MAX( DIFF, CABS1( X( I, J )-XACT( I, J ) ) )
+   10    CONTINUE
+*
+         IF( XNORM.GT.ONE ) THEN
+            GO TO 20
+         ELSE IF( DIFF.LE.OVFL*XNORM ) THEN
+            GO TO 20
+         ELSE
+            ERRBND = ONE / EPS
+            GO TO 30
+         END IF
+*
+   20    CONTINUE
+         IF( DIFF / XNORM.LE.FERR( J ) ) THEN
+            ERRBND = MAX( ERRBND, ( DIFF / XNORM ) / FERR( J ) )
+         ELSE
+            ERRBND = ONE / EPS
+         END IF
+   30 CONTINUE
+      RESLTS( 1 ) = ERRBND
+*
+*     Test 2:  Compute the maximum of BERR / ( (n+1)*EPS + (*) ), where
+*     (*) = (n+1)*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
+*
+      DO 90 K = 1, NRHS
+         DO 80 I = 1, N
+            TMP = CABS1( B( I, K ) )
+            IF( UPPER ) THEN
+               JC = ( ( I-1 )*I ) / 2
+               DO 40 J = 1, I - 1
+                  TMP = TMP + CABS1( AP( JC+J ) )*CABS1( X( J, K ) )
+   40          CONTINUE
+               TMP = TMP + ABS( REAL( AP( JC+I ) ) )*CABS1( X( I, K ) )
+               JC = JC + I + I
+               DO 50 J = I + 1, N
+                  TMP = TMP + CABS1( AP( JC ) )*CABS1( X( J, K ) )
+                  JC = JC + J
+   50          CONTINUE
+            ELSE
+               JC = I
+               DO 60 J = 1, I - 1
+                  TMP = TMP + CABS1( AP( JC ) )*CABS1( X( J, K ) )
+                  JC = JC + N - J
+   60          CONTINUE
+               TMP = TMP + ABS( REAL( AP( JC ) ) )*CABS1( X( I, K ) )
+               DO 70 J = I + 1, N
+                  TMP = TMP + CABS1( AP( JC+J-I ) )*CABS1( X( J, K ) )
+   70          CONTINUE
+            END IF
+            IF( I.EQ.1 ) THEN
+               AXBI = TMP
+            ELSE
+               AXBI = MIN( AXBI, TMP )
+            END IF
+   80    CONTINUE
+         TMP = BERR( K ) / ( ( N+1 )*EPS+( N+1 )*UNFL /
+     $         MAX( AXBI, ( N+1 )*UNFL ) )
+         IF( K.EQ.1 ) THEN
+            RESLTS( 2 ) = TMP
+         ELSE
+            RESLTS( 2 ) = MAX( RESLTS( 2 ), TMP )
+         END IF
+   90 CONTINUE
+*
+      RETURN
+*
+*     End of CPPT05
+*
+      END