1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
|
//
// Copyright (c) Microsoft. All rights reserved.
// Licensed under the MIT license. See LICENSE file in the project root for full license information.
//
.intel_syntax noprefix
#include "unixasmmacros.inc"
#include "asmconstants.h"
//////////////////////////////////////////////////////////////////////////
//
// PrecodeFixupThunk
//
// The call in fixup precode initally points to this function.
// The pupose of this function is to load the MethodDesc and forward the call the prestub.
//
// EXTERN_C VOID __stdcall PrecodeFixupThunk()
LEAF_ENTRY PrecodeFixupThunk, _TEXT
pop rax // Pop the return address. It points right after the call instruction in the precode.
// Inline computation done by FixupPrecode::GetMethodDesc()
movzx r10,byte ptr [rax+2] // m_PrecodeChunkIndex
movzx r11,byte ptr [rax+1] // m_MethodDescChunkIndex
mov rax,qword ptr [rax+r10*8+3]
lea METHODDESC_REGISTER,[rax+r11*8]
// Tail call to prestub
jmp ThePreStub
LEAF_END PrecodeFixupThunk, _TEXT
// EXTERN_C int __fastcall HelperMethodFrameRestoreState(
// INDEBUG_COMMA(HelperMethodFrame *pFrame)
// MachState *pState
// )
LEAF_ENTRY HelperMethodFrameRestoreState, _TEXT
#ifdef _DEBUG
mov rdi, rsi
#endif
// Check if the MachState is valid
xor eax, eax
cmp qword ptr [rdi + OFFSETOF__MachState___pRetAddr], rax
jne DoRestore
REPRET
DoRestore:
//
// If a preserved register were pushed onto the stack between
// the managed caller and the H_M_F, m_pReg will point to its
// location on the stack and it would have been updated on the
// stack by the GC already and it will be popped back into the
// appropriate register when the appropriate epilog is run.
//
// Otherwise, the register is preserved across all the code
// in this HCALL or FCALL, so we need to update those registers
// here because the GC will have updated our copies in the
// frame.
//
// So, if m_pReg points into the MachState, we need to update
// the register here. That's what this macro does.
//
#define RestoreReg(reg) \
lea rax, [rdi + OFFSETOF__MachState__m_Capture##reg]; \
mov rdx, [rdi + OFFSETOF__MachState__m_p##reg]; \
cmp rax, rdx; \
cmove reg, [rax];
// .endm
//RestoreReg(Rdi)
//RestoreReg(Rsi)
RestoreReg(Rbx)
RestoreReg(Rbp)
RestoreReg(R12)
RestoreReg(R13)
RestoreReg(R14)
RestoreReg(R15)
xor eax, eax
ret
LEAF_END HelperMethodFrameRestoreState, _TEXT
//////////////////////////////////////////////////////////////////////////
//
// NDirectImportThunk
//
// In addition to being called by the EE, this function can be called
// directly from code generated by JIT64 for CRT optimized direct
// P/Invoke calls. If it is modified, the JIT64 compiler's code
// generation will need to altered accordingly.
//
// EXTERN_C VOID __stdcall NDirectImportThunk()//
NESTED_ENTRY NDirectImportThunk, _TEXT
//
// Save integer parameter registers.
// Make sure to preserve r11 as well as it is used to pass the stack argument size from JIT
//
PUSH_ARGUMENT_REGISTERS
push r11
//
// Allocate space for XMM parameter registers
//
alloc_stack 0x80
SAVE_FLOAT_ARGUMENT_REGISTERS 0
END_PROLOGUE
//
// Call NDirectImportWorker w/ the NDirectMethodDesc*
//
mov rdi, METHODDESC_REGISTER
call NDirectImportWorker
RESTORE_FLOAT_ARGUMENT_REGISTERS 0
//
// epilogue, rax contains the native target address
//
add rsp, 0x80
//
// Restore integer parameter registers and r11
//
pop r11
POP_ARGUMENT_REGISTERS
TAILJMP_RAX
NESTED_END NDirectImportThunk, _TEXT
// EXTERN_C void moveOWord(LPVOID* src, LPVOID* target);
// <NOTE>
// MOVDQA is not an atomic operation. You need to call this function in a crst.
// </NOTE>
LEAF_ENTRY moveOWord, _TEXT
movdqa xmm0, [rdi]
movdqa [rsi], xmm0
ret
LEAF_END moveOWord, _TEXT
//------------------------------------------------
// JIT_RareDisableHelper
//
// The JIT expects this helper to preserve registers used for return values
//
NESTED_ENTRY JIT_RareDisableHelper, _TEXT
// First integer return register
push rax
// Second integer return register
push rdx
alloc_stack 0x28
END_PROLOGUE
// First float return register
movdqa [rsp], xmm0
// Second float return register
movdqa [rsp+0x10], xmm1
call JIT_RareDisableHelperWorker
movdqa xmm0, [rsp]
movdqa xmm1, [rsp+0x10]
add rsp, 0x28
pop rdx
pop rax
ret
NESTED_END JIT_RareDisableHelper, _TEXT
|