#!/usr/bin/perl -w

use Net::SSL ();
BEGIN {
  $ENV{PERL_LWP_SSL_VERIFY_HOSTNAME} = 0,
  unshift @INC, ($::ENV{'BUILD_DIR'} || '/usr/lib/build');
}

use LWP::UserAgent;
use URI;
use File::Path;
use File::Basename;

use strict;

die "USAGE: $0 DIR URLS..." unless $#ARGV >= 1;

my $dir = shift @ARGV;

my $ua = LWP::UserAgent->new(
  agent => "openSUSE build script",
  timeout => 42);

for my $url (@ARGV) {
  if ($url =~ /^zypp:\/\/([^\/]*)\/?/) {
    use Build::Zypp;
    my $repo = Build::Zypp::parsecfg($1);
    die "can't parse $1\n" unless $repo;
    die "missing url in repo ".$repo->{'name'}."\n" unless exists $repo->{'baseurl'};
    my $u = $repo->{'baseurl'};
    $u .= '/' unless substr($u, -1, 1) eq '/';
    $url =~ s/^zypp:\/\/[^\/]*\/*//;
    $url = URI->new($u.$url)
  } else {
    $url = URI->new($url);
  }
  $ua->env_proxy  if $url->scheme ne 'https';
  my $dest = "$dir/".basename($url->path);
  unlink($dest);	# just in case
  my $retry = 3;
  while ($retry--) {
    my $res = $ua->mirror($url, $dest);
    last if $res->is_success;
    # if it's a redirect we probably got a bad mirror and should just retry
    die "reqesting $url failed: ".$res->status_line."\n" unless $retry && $res->previous;
    warn "retrying $url\n";
  }
}

# vim:sw=2