blob: 789e585357ea0189e061ca6ce42d1809d1c100a8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
|
nnas_include(TargetRequire)
unset(REQUIRED_TARGETS)
list(APPEND REQUIRED_TARGETS circle-inspect)
list(APPEND REQUIRED_TARGETS circle-verify)
list(APPEND REQUIRED_TARGETS tf2circle)
list(APPEND REQUIRED_TARGETS tfkit)
list(APPEND REQUIRED_TARGETS dredd_rule_lib)
TargetRequire_Return(${REQUIRED_TARGETS})
nncc_find_resource(TensorFlowTests)
set(MODEL_REPO "${TensorFlowTests_DIR}") # Where to find text models to test
unset(KEYS)
unset(DEPS)
#
# processing models in test.lst and test.local.lst
#
# Example)
#
# Add(NET_0025 RULE test.rule)
# -> Read test.pbtxt file under res/TensorFlowTests/NET_0025 and create "NET_0025.circle"
# Then the circle is tested against rules in test.rule file.
#
macro(Add MODEL_DIR)
set(ARG_OPTION)
set(ARG_ONE_VALUE RULE) # rule file name
set(ARG_MULTI_VALUE)
cmake_parse_arguments(ARG "${ARG_OPTION}" "${ARG_ONE_VALUE}" "${ARG_MULTI_VALUE}" ${ARGN})
if(NOT ARG_RULE)
message( FATAL_ERROR "RULE is mandadatory arg" )
endif()
set(RULE_FILENAME ${ARG_RULE})
set(TARGET_TESTNAME "${MODEL_DIR}")
set(MODEL_SOURCE_DIR "${MODEL_REPO}/${MODEL_DIR}")
set(TXT_SOURCE_PBTXT_PATH "${MODEL_SOURCE_DIR}/test.pbtxt")
set(TXT_SOURCE_INFO_PATH "${MODEL_SOURCE_DIR}/test.info")
set(TXT_SOURCE_RULE_PATH "${MODEL_SOURCE_DIR}/${RULE_FILENAME}")
set(TXT_TARGET_PB_PATH "${CMAKE_CURRENT_BINARY_DIR}/${TARGET_TESTNAME}.pb")
set(TXT_TARGET_PBTXT_PATH "${CMAKE_CURRENT_BINARY_DIR}/${TARGET_TESTNAME}.pbtxt")
set(TXT_TARGET_INFO_PATH "${CMAKE_CURRENT_BINARY_DIR}/${TARGET_TESTNAME}.info")
set(TXT_TARGET_RULE_PATH "${CMAKE_CURRENT_BINARY_DIR}/${TARGET_TESTNAME}.rule")
if(NOT EXISTS "${TXT_SOURCE_PBTXT_PATH}")
message(FATAL_ERROR "${TXT_SOURCE_PBTXT_PATH} - pbtxt file does not exist")
endif(NOT EXISTS "${TXT_SOURCE_PBTXT_PATH}")
if(NOT EXISTS "${TXT_SOURCE_INFO_PATH}")
message(FATAL_ERROR "${TXT_SOURCE_INFO_PATH} - info file does not exist")
endif(NOT EXISTS "${TXT_SOURCE_INFO_PATH}")
if(NOT EXISTS "${TXT_SOURCE_RULE_PATH}")
message(FATAL_ERROR "${TXT_SOURCE_RULE_PATH} - rule file does not exist")
endif(NOT EXISTS "${TXT_SOURCE_RULE_PATH}")
# Copy .pbtxt
add_custom_command(OUTPUT ${TXT_TARGET_PBTXT_PATH}
COMMAND ${CMAKE_COMMAND} -E copy "${TXT_SOURCE_PBTXT_PATH}" "${TXT_TARGET_PBTXT_PATH}"
DEPENDS ${TXT_SOURCE_PBTXT_PATH}
COMMENT "Generate ${TXT_TARGET_PBTXT_PATH}"
)
# Copy .info
add_custom_command(OUTPUT ${TXT_TARGET_INFO_PATH}
COMMAND ${CMAKE_COMMAND} -E copy "${TXT_SOURCE_INFO_PATH}" "${TXT_TARGET_INFO_PATH}"
DEPENDS ${TXT_SOURCE_INFO_PATH}
COMMENT "Generate ${TXT_TARGET_INFO_PATH}"
)
# Copy .rule
add_custom_command(OUTPUT ${TXT_TARGET_RULE_PATH}
COMMAND ${CMAKE_COMMAND} -E copy "${TXT_SOURCE_RULE_PATH}" "${TXT_TARGET_RULE_PATH}"
DEPENDS ${TXT_SOURCE_RULE_PATH}
COMMENT "Generate ${TXT_TARGET_RULE_PATH}"
)
# Generate .pb from .pbtxt
add_custom_command(OUTPUT ${TXT_TARGET_PB_PATH}
COMMAND $<TARGET_FILE:tfkit> encode ${TXT_TARGET_PBTXT_PATH} ${TXT_TARGET_PB_PATH}
DEPENDS ${TXT_TARGET_PBTXT_PATH}
COMMENT "Generate ${TXT_TARGET_PB_PATH}"
)
# Generate .test file which declares path of target pb, info, rule files
# this file is used inside runner.sh
set(TEST_CONFIG_FILE "${CMAKE_CURRENT_BINARY_DIR}/${TARGET_TESTNAME}.test")
add_custom_command(
OUTPUT ${TEST_CONFIG_FILE}
COMMAND ${CMAKE_COMMAND} -E remove -f ${TEST_CONFIG_FILE}
COMMAND ${CMAKE_COMMAND} -E echo 'MODEL_PB_PATH="${TXT_TARGET_PB_PATH}"' >> ${TEST_CONFIG_FILE}
COMMAND ${CMAKE_COMMAND} -E echo 'MODEL_INFO_PATH="${TXT_TARGET_INFO_PATH}"' >> ${TEST_CONFIG_FILE}
COMMAND ${CMAKE_COMMAND} -E echo 'MODEL_RULE_PATH="${TXT_TARGET_RULE_PATH}"' >> ${TEST_CONFIG_FILE}
DEPENDS
${TXT_TARGET_PB_PATH}
${TXT_TARGET_INFO_PATH}
${TXT_TARGET_RULE_PATH}
COMMENT "Generate ${TARGET_TESTNAME} configuration for TXT"
)
list(APPEND DEPS "${TEST_CONFIG_FILE}")
list(APPEND KEYS "${TARGET_TESTNAME}")
endmacro(Add)
# Read "test.lst"
include("test.lst")
# Read "test.local.lst" if exists
include("test.local.lst" OPTIONAL)
#
# Generate toolchain.config
#
set(TOOLCHAIN_CONFIG "${CMAKE_CURRENT_BINARY_DIR}/toolchain.config")
add_custom_command(
OUTPUT ${TOOLCHAIN_CONFIG}
COMMAND ${CMAKE_COMMAND} -E remove -f ${TOOLCHAIN_CONFIG}
COMMAND ${CMAKE_COMMAND} -E echo 'CIRCLE_INSPECT_PATH=\"$<TARGET_FILE:circle-inspect>\"' >> ${TOOLCHAIN_CONFIG}
COMMAND ${CMAKE_COMMAND} -E echo 'CIRCLE_VERIFY_PATH=\"$<TARGET_FILE:circle-verify>\"' >> ${TOOLCHAIN_CONFIG}
COMMAND ${CMAKE_COMMAND} -E echo 'TF2CIRCLE_PATH=\"$<TARGET_FILE:tf2circle>\"' >> ${TOOLCHAIN_CONFIG}
# add more if new excutable file is needed in runner.sh and rule-lib.sh
DEPENDS
circle-inspect
circle-verify
tf2circle
COMMENT "Generate toolchin configuration"
)
list(APPEND DEPS "${TOOLCHAIN_CONFIG}")
#
# copy runner.sh
#
set(SOURCE_RUNNER "${CMAKE_CURRENT_SOURCE_DIR}/runner.sh")
set(TARGET_RUNNER "${CMAKE_CURRENT_BINARY_DIR}/runner.sh")
add_custom_command(
OUTPUT ${TARGET_RUNNER}
COMMAND ${CMAKE_COMMAND} -E copy "${SOURCE_RUNNER}" "${TARGET_RUNNER}"
DEPENDS ${SOURCE_RUNNER}
COMMENT "Generate test runner"
)
list(APPEND DEPS "${TARGET_RUNNER}")
#
# copy rule-lib.sh (a library of shell script functions)
#
# getting path for rule-lib.sh in dredd-rule-lib
get_target_property(DREDD_RULE_LIB_DIR dredd_rule_lib BINARY_DIR)
set(SOURCE_RULE_LIB "${DREDD_RULE_LIB_DIR}/rule-lib.sh")
set(TARGET_RULE_LIB "${CMAKE_CURRENT_BINARY_DIR}/rule-lib.sh")
add_custom_command(
OUTPUT ${TARGET_RULE_LIB}
COMMAND ${CMAKE_COMMAND} -E copy "${SOURCE_RULE_LIB}" "${TARGET_RULE_LIB}"
DEPENDS ${SOURCE_RULE_LIB}
COMMENT "Generate rule lib"
)
list(APPEND DEPS "${TARGET_RULE_LIB}")
# Generate dependencies
add_custom_target(tf2circle_dredd_pbtxt_deps ALL DEPENDS ${DEPS})
add_test(
NAME tf2circle_dredd_pbtxt_test
COMMAND
"${TARGET_RUNNER}"
"${TOOLCHAIN_CONFIG}"
${KEYS}
)
|
