/*
 * Copyright (c) 2018 Samsung Electronics Co., Ltd. All Rights Reserved
 * Copyright (c) 2016-2018 ARM Limited.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
#include "helpers.h"
#define SUB(x, y) (x) - (y)

#ifndef VEC_SIZE
#define VEC_SIZE  1
#endif

#if defined(OFFSET_IN1) && defined(OFFSET_IN2) && defined(SCALE_IN1) && defined(SCALE_IN2) && defined(DATA_TYPE_OUT)

#define VEC_FLOAT VEC_DATA_TYPE(float, VEC_SIZE)
#define VEC_INT VEC_DATA_TYPE(int, VEC_SIZE)
#define VEC_OUT VEC_DATA_TYPE(DATA_TYPE_OUT, VEC_SIZE)

/** Returns the truth value of comparison .
 * @attention Offset and Scale of both input should be given as a preprocessor argument using -DOFFSET_IN1=int, -DOFFSET_IN2=int, -DSCALE_IN1=float and -DSCALE_IN2=float. e.g. -DOFFSET_IN1=1, -DOFFSET_IN2=0, -DSCALE_IN1=0.5, -DSCALE_IN2=0.5
 * @attention Vector size should be given as a preprocessor argument using -DVEC_SIZE=size. e.g. -DVEC_SIZE=16
 * @attention Operation type(code) specifying which operation to perform should be passed as preprocessor argument using
 * -DOP_CODE = number. e.g. -DOP_CODE=1
 *
 * @param[in]  input1_ptr                            Pointer to the source tensor. Supported data types: QASYMM8
 * @param[in]  input1_stride_x                       Stride of the source tensor in X dimension (in bytes)
 * @param[in]  input1_step_x                         input1_stride_x * number of elements along X processed per workitem(in bytes)
 * @param[in]  input1_stride_y                       Stride of the source tensor in Y dimension (in bytes)
 * @param[in]  input1_step_y                         input1_stride_y * number of elements along Y processed per workitem(in bytes)
 * @param[in]  input1_stride_z                       Stride of the source tensor in Z dimension (in bytes)
 * @param[in]  input1_step_z                         input1_stride_z * number of elements along Z processed per workitem(in bytes)
 * @param[in]  input1_offset_first_element_in_bytes  The offset of the first element in the source tensor
 *
 * @param[in]  input2_ptr                            Pointer to the source tensor. Supported data types: QASYMM8
 * @param[in]  input2_stride_x                       Stride of the source tensor in X dimension (in bytes)
 * @param[in]  input2_step_x                         input2_stride_x * number of elements along X processed per workitem(in bytes)
 * @param[in]  input2_stride_y                       Stride of the source tensor in Y dimension (in bytes)
 * @param[in]  input2_step_y                         input2_stride_y * number of elements along Y processed per workitem(in bytes)
 * @param[in]  input2_stride_z                       Stride of the source tensor in Z dimension (in bytes)
 * @param[in]  input2_step_z                         input2_stride_z * number of elements along Z processed per workitem(in bytes)
 * @param[in]  input2_offset_first_element_in_bytes  The offset of the first element in the source tensor
 *
 * @param[out] output_ptr                           Pointer to the destination tensor. Supported data types: QASYMM8
 * @param[in]  output_stride_x                      Stride of the destination tensor in X dimension (in bytes)
 * @param[in]  output_step_x                        output_stride_x * number of elements along X processed per workitem(in bytes)
 * @param[in]  output_stride_y                      Stride of the destination tensor in Y dimension (in bytes)
 * @param[in]  output_step_y                        output_stride_y * number of elements along Y processed per workitem(in bytes)
 * @param[in]  output_stride_z                      Stride of the destination tensor in Z dimension (in bytes)
 * @param[in]  output_step_z                        output_stride_z * number of elements along Z processed per workitem(in bytes)
 * @param[in]  output_offset_first_element_in_bytes The offset of the first element in the destination tensor
 */
__kernel void comparison_op_qasymm8(
    TENSOR3D_DECLARATION(in1),
    TENSOR3D_DECLARATION(in2),
    TENSOR3D_DECLARATION(out))
{
    // Get pixels pointer
    Tensor3D in1 = CONVERT_TO_TENSOR3D_STRUCT(in1);
    Tensor3D in2 = CONVERT_TO_TENSOR3D_STRUCT(in2);
    Tensor3D out = CONVERT_TO_TENSOR3D_STRUCT(out);

    VEC_INT in_a = CONVERT(VLOAD(VEC_SIZE)(0, (__global uchar *)in1.ptr), VEC_INT);
    VEC_INT in_b = CONVERT(VLOAD(VEC_SIZE)(0, (__global uchar *)in2.ptr), VEC_INT);

    in_a = SUB(in_a, (VEC_INT)((int)OFFSET_IN1));
    in_b = SUB(in_b, (VEC_INT)((int)OFFSET_IN2));

    const VEC_FLOAT in1f32  = CONVERT(in_a, VEC_FLOAT) * (VEC_FLOAT)((float)SCALE_IN1);
    const VEC_FLOAT in2f32  = CONVERT(in_b, VEC_FLOAT) * (VEC_FLOAT)((float)SCALE_IN2);

    #if OPCODE == 1 //EQUAL QUANTIZED
      VSTORE(VEC_SIZE)(CONVERT(in1f32 == in2f32, VEC_OUT), 0, (__global DATA_TYPE_OUT *)out.ptr);

    #elif OPCODE == 2 //NOT EQUAL QUANTIZED
      VSTORE(VEC_SIZE)(CONVERT(in1f32 != in2f32, VEC_OUT), 0, (__global DATA_TYPE_OUT *)out.ptr);

    #else // OP NOT SUPPORTED
      return;

    #endif
}
#endif // defined(OFFSET_IN1) && defined(OFFSET_IN2) && defined(SCALE_IN1) && defined(SCALE_IN2) && defined(DATA_TYPE_OUT)